组合扩展方法

Question

我正在尝试编写 2 个扩展方法来处理 Enum 类型。一种是使用描述属性为枚举选项提供更好的解释，第二种方法是列出枚举选项及其描述以在选择列表或某种集合中使用。

您可以在这里阅读我到目前为止的代码：

    <Extension()> _
    Public Function ToDescriptionString(ByVal en As System.Enum) As String

        Dim type As Type = en.GetType
        Dim entries() As String = en.ToString().Split(","c)
        Dim description(entries.Length) As String

        For i = 0 To entries.Length - 1
            Dim fieldInfo = type.GetField(entries(i).Trim())
            Dim attributes() = DirectCast(fieldInfo.GetCustomAttributes(GetType(DescriptionAttribute), False), DescriptionAttribute())

            description(i) = If(attributes.Length > 0, attributes(0).Description, entries(i).Trim())
        Next

        Return String.Join(", ", description)

    End Function

    <Extension()> _
    Public Function ToListFirstTry(ByVal en As System.Enum) As IEnumerable

        Dim type As Type = en.GetType

        Dim items = From item In System.Enum.GetValues(type) _
           Select New With {.Value = item, .Text = item.ToDescriptionString}

        Return items

    End Function

    <Extension()> _
    Public Function ToListSecondTry(ByVal en As System.Enum) As IEnumerable

        Dim list As New Dictionary(Of Integer, String)
        Dim enumValues As Array = System.Enum.GetValues(en.GetType)

        For Each value In enumValues
            list.Add(value, value.ToDescriptionString)
        Next

        Return list

    End Function

所以我的问题是两种扩展方法不能很好地协同工作。将枚举选项转换为可枚举的方法不能使用扩展方法来获取描述。

我找到了各种各样的例子来实现两者之一，但从未将它们结合在一起。我做错了什么？我对这些新的 .NET 3.5 东西还是很陌生。

Answer 1

问题在于 Enum.GetValues 仅返回弱类型 Array。

试试这个：（

Public Function ToListFirstTry(ByVal en As System.Enum) As IEnumerable

    Dim type As Type = en.GetType

    Dim items = From item In System.Enum.GetValues(type).Cast(Of Enum)() _
       Select New With {.Value = item, .Text = item.ToDescriptionString}

    Return items

End Function

看起来 VB 查询中显式键入的范围变量与 C# 中的含义不同。）