在 Moose 中，如何在设置属性时修改它？

Question

如果您有一个在设置时需要修改的属性，是否有一种巧妙的方法可以自己编写访问器并直接修改 $self 的内容，就像完成的那样在这个例子中？

package Foo;
use Moose;

has 'bar' => (
    isa => 'Str',
    reader => 'get_bar',
);

sub set_bar {
    my ($self, $bar) = @_;
    $self->{bar} = "modified: $bar";
}

我考虑过触发，但似乎需要相同的方法。

直接使用 $self 中的哈希引用被认为是 Moose，还是我担心的是一个不存在的问题？

Answer 1

您可以使用方法修饰符“around”。像这样的事情：

has 'bar' => (
    isa    => 'Str',
    reader => 'get_bar',
    writer => 'set_bar'
);

around 'set_bar' => sub {
    my ($next, $self, $bar) = @_;
    $self->$next( "Modified: $bar" );
};

是的，直接使用哈希值被认为是不好的做法。

另外，请不要认为我提供的选项一定是正确的。在大多数情况下，使用子类型和强制转换将是正确的解决方案 - 如果您根据可以在整个应用程序中重用的类型来考虑您的参数，将导致更好的设计，而不是可以进行的任意修改使用“周围”完成。请参阅@daotoad 的回答。

Answer 2

我不确定您需要什么样的修改，但您也许可以通过使用类型强制来实现您所需要的：

package Foo;
use Moose;

use Moose::Util::TypeConstraints;

subtype 'ModStr' 
    => as 'Str'
    => where { /^modified: /};

coerce 'ModStr'
    => from 'Str'
    => via { "modified: $_" };

has 'bar' => ( 
    isa => 'ModStr', 
    is  => 'rw', 
    coerce => 1,
);

如果您使用这种方法，则并非所有值都会被修改。任何通过 ModStr 验证的内容都将直接使用：

my $f = Foo->new();
$f->bar('modified: bar');  # Set without modification

这个弱点可能是好的，也可能使这种方法无法使用。在适当的情况下，这甚至可能是一种优势。

Answer 3

我认为在 trigger< 中使用哈希引用很好/a> 像这样：

package Foo;
use Moose;

has 'bar' => ( 
    isa => 'Str', 
    is  => 'rw', 
    trigger => sub { $_[0]->{bar} = "modified: $_[1]" },
);

当 bar 参数与构造函数一起传递时，触发器也会触发。如果您定义自己的 set_bar 方法或使用方法修饰符，则不会发生这种情况。

回复：哈希引用 - 一般来说，我认为最好坚持使用属性设置器/获取器，除非（如上面的触发器）没有简单的替代方案。

顺便说一句，您可能会发现这篇最近关于触发器的帖子，作者：没什么有趣的。

Answer 4

如果直接处理哈希引起您的担忧，您可以指定一个备用编写器，然后在您自己适当命名的“公共”编写器中使用它。

package Foo;
use Moose;

has 'bar' => (
   isa => 'Str',
   reader => 'get_bar',
   writer => '_set_bar',
);

sub set_bar {
   my $self = shift;
   my @args = @_;
   # play with args;
   return $self->_set_bar(@args);
}

我认为这是一个很好的方法，或者说触发器，这取决于你需要何时以及如何操纵参数。

（免责声明：从内存中编写的未经测试的代码，在具有片状边缘访问的上网本上浏览SO）