我可以更改 SAS 中 CALL EXECUTE 堆栈的执行顺序吗？

Question

我使用 SAS 9.1.3 在 DATA 步骤中调用宏，但该宏生成 PROC REPORT 步骤，因此我使用 CALL EXECUTE 来调用它，生成所有这些 PROC REPORT 步骤，然后在数据步。

我使用的是一个数组，每次都会对该数组中的每个元素执行该宏：

DATA macro_test;
  ARRAY questions[3] $ 32 ('question1' 'question2' 'question3');

  DO i=1 to 3;
    a_question = questions(i);
    CALL EXECUTE( "%report_by_question(a_question)" ); 
  end;

RUN;

问题是，报告输出（通常）向后输出 - 它将首先打印问题 3，然后打印问题 2，然后

打印问题 1。一种修改 CALL EXECUTE 的执行顺序的方法，以便我可以按顺序打印问题报告，或者它只是做自己的事情？

谢谢！

Answer 1

我假设您对 callexecute() 行的意思更像是这样：

 CALL EXECUTE( "%report_by_question(" || trim(left(a_question)) || ");" ); 

使用测试宏，我得到一些像这样的日志行，显示 callexecute()s正在以正确的顺序发生。你得到类似的东西吗？

宏

%macro report_by_question(a);
data test_&a;
  do i=1 to 10000000;
    output;
  end;
run;
%mend;

日志

NOTE: CALL EXECUTE generated line.
1   + data test_question1;   do i=1 to 10000000;     output;   end; run;

NOTE: The data set WORK.TEST_QUESTION1 has 10000000 observations and 1 variables.
NOTE: DATA statement used (Total process time):
      real time           6.14 seconds
      cpu time            0.45 seconds


1   +                                                                   ;
2   + data test_question2;   do i=1 to 10000000;     output;   end; run;

NOTE: The data set WORK.TEST_QUESTION2 has 10000000 observations and 1 variables.
NOTE: DATA statement used (Total process time):
      real time           3.87 seconds
      cpu time            0.53 seconds


2   +                                                                   ;
3   + data test_question3;   do i=1 to 10000000;     output;   end; run;

NOTE: The data set WORK.TEST_QUESTION3 has 10000000 observations and 1 variables.
NOTE: DATA statement used (Total process time):
      real time           3.12 seconds
      cpu time            0.45 seconds

Answer 2

数据步骤被编译然后执行。 调用execute(str);将str推入输入队列，以便在数据步骤执行完成后将它们弹出。订单被保留，期间。

但是，如果您将宏调用放在双引号字符串中，如下所示：
调用execute("%report(q)");
然后在编译数据步骤时（甚至在数据步骤开始运行之前）调用宏。

如果您不想在编译时调用宏，则可以用宏引用它或将其放在单引号字符串中。下面是一个例子。希望这有帮助。

/* create a dataset with 1 var and 3 obs */
data qs;
  input q $;
cards;
q1
q2
q3
;
run;

/* reporting macro -- a mockup */
%macro report(q=);
  %put report for q=&q;
%mend  report;

/* call the reporting macro for each q */
data _null_;  
  set qs;     
  macro = catx(q, '%report(q=', ')'); 
  call execute(macro);
run;

/* on log
report for q=q1
report for q=q2
report for q=q3
*/


/* to show what happens when the
   macro is invoked during the compile
   time */
data _null_;
  call execute("%report(q=q1)");
  put "after call execute";
run;
/* on log
1   data _null_;
2     call execute("%report(q=q1)");
report for q=q1
3     put "after call execute";
4   run;
after call execute
*/

Answer 3

我更喜欢使用宏语言来完成与宏相关的所有事情。我想权衡是你的程序中散布着很少的宏。但是，要防止程序生成报告，只需注释掉宏调用 (*%loopit;) 此外，您不必键入“question1”、“question2”、“question3”等等!!!
希望这对您有用！

%macro report_by_question(input);
    %put "Question: " &input;
%mend;

%macro loopit;
    %do i=1 %to 3;
        %report_by_question("question&i.");
    %end;
%mend loopit;
%loopit;