使用 Perl，如何使用 CSV 文件中的值创建图表？

Question

我对此很陌生，需要有关如何完成这项任务的线索。我有一个包含以下示例数据的 csv 文件：

site,type,2009-01-01,2009-01-02,....
X,A,12,10,...
X,B,10,23,...
Y,A,20,33,...
Y,B,3,12,...

and so on....

我想创建一个 perl 脚本来从 csv 文件读取数据（根据给定的用户输入）并创建 XY（散点）图表。假设我想为日期 2009-01-01 创建一个图表并输入 B。用户应输入类似“2009-01-01 B”的内容，并且应使用 CSV 文件中的值创建图表。

有人可以建议我一些代码来开始吗？

Answer 1

不要从代码开始。从 CPAN 开始。

CSV 和 分散

Answer 2

在这里，您可以从一些代码开始：

#!/usr/bin/perl -w
use strict;

use Text::CSV;
use GD;
use Getopt::Long;

当然，您可以使用您想要的任何模块来代替 GD。

Answer 3

好的，仅用于娱乐目的：

#!/usr/bin/perl

use strict;
use warnings;

use DBI;
use List::AllUtils qw( each_array );

my $dbh = DBI->connect("DBI:CSV:f_dir=.", undef, undef, {
        RaiseError => 1, AutoCommit => 1,
    }
);

my $sth = $dbh->prepare(qq{
    SELECT d20090101 FROM test.csv WHERE type = ? and site = ?
});

$sth->execute('B', 'X');
my @x = map { $_->[0] } @{ $sth->fetchall_arrayref };

$sth->execute('B', 'Y');
my @y = map { $_->[0] } @{ $sth->fetchall_arrayref };

my @xy;

my $ea = each_array(@x, @y);
while ( my @vals = $ea->() ) {
    push @xy, \@vals;
}

my @canvas;
push @canvas, [ '|', (' ') x 40 ] for 1 .. 40;
push @canvas, [ '+', ('-') x 40 ];

for my $coord ( @xy ) {
    warn "coords=@$coord\n";
    my ($x, $y) = @$coord;
    $canvas[40 - $y]->[$x + 1] = '*';
}

print join "\n", map { join '', @$_ } @canvas;

添加坐标轴并在 ScatterPlot——一个真正令人失望的模块——留给读者作为练习。

请注意，当涉及到 SQL 时我总是不得不作弊。我希望有一个适当的 JOIN 来消除对 @x、@y 和 each_array 的需要。

输出：

|
|
|
|            *
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|          *
|
|
+----------------------------------------

Answer 4

我需要自己制作一些散点图，所以我尝试了其他答案中建议的模块。根据我的口味， GD::Graph::Cartesian 太大了，并且该模块没有提供控制此参数的方法，因此我破解了 Cartesian.pm 的副本（搜索 iconsize 如果你想做同样的事情）。

use strict;
use warnings;
use Text::CSV;
use GD::Graph::Cartesian;

# Parse CSV file and convert the data for the
# requested $type and $date into a list of [X,Y] pairs.
my ($csv_file, $type, $date) = @ARGV;
my @xy_points;
my %i = ( X => -1, Y => -1 );
open(my $csv_fh, '<', $csv_file) or die $!;
my $parser = Text::CSV->new();
$parser->column_names( $parser->getline($csv_fh) );
while ( defined( my $hr = $parser->getline_hr($csv_fh) ) ){
    next unless $hr->{type} eq $type;
    my $xy = $hr->{site};
    $xy_points[++ $i{$xy}][$xy eq 'X' ? 0 : 1] = $hr->{$date};
}

# Make a graph.
my $graph = GD::Graph::Cartesian->new(
    width   => 400, # Image size (in pixels, not X-Y coordinates).
    height  => 400,
    borderx => 20,  # Margins (also pixels).
    bordery => 20,
    strings => [[ 20, 50, 'Graph title' ]],
    lines => [
        [ 0,0, 50,0 ], # Draw an X axis.
        [ 0,0,  0,50], # Draw a Y axis.
    ],
    points => \@xy_points, # The data.
);
open(my $png_file, '>', 'some_data.png') or die $!;
binmode $png_file;
print $png_file $graph->draw;