如何绑定到 ArrayCollection 中的第一项？

Question

我的应用程序使用 MVC 模型。该模型包含一个 Bindable 类 (BindableItemsClass)，其中包含一个 ArrayCollection。我想将视图中的一些内容绑定到 Bindable 类的 ArrayCollection 中的第一项（因此属性“firstItem”）。

问题是，当使用 setter 'set firstItem(value:Object)' 时，绑定到该属性的视图组件不会更新。

有没有办法手动触发属性“firstItem”的绑定？

[Bindable]
public class BindableItemsClass extends EventDispatcher
{
    private var _items:ArrayCollection;

    public function get items():ArrayCollection
    {
        return _items;
    }

    public function set items(value:ArrayCollection):void
    {
        _items = value;
    }

    public function get firstItem():Object
    {
        if(_items && items.length>0)
            return items[0];
        else
            return null;
    }

    public function set firstItem(value:Object):void
    {
        if(value)
            items = new ArrayCollection([value]);
        else
            items = new ArrayCollection();
    }
}

Answer 1

调度一个更改事件来触发 setter 中的绑定：

dispatchEvent(new FlexEvent(FlexEvent.DATA_CHANGE));

这应该有效。

如果没有，那么您可能还需要注释您的 getter：

[Bindable("dataChange")]
public function get firstItem():Object
{
    if(_items && items.length>0)
        return items[0];
    else
        return null;
}

这显式定义了函数的绑定侦听器，因此监视此侦听器的属性将了解要侦听的事件。