如何搜索整个 CVS 存储库（所有分支/历史记录/评论）？

Question

如果我想基本上 grep 存储库中的每一行，有没有办法做到这一点？我知道对于大型项目来说这需要很长时间。

如果不是全部包括在内，至少只是当前分支及其整个源历史记录？

编辑：我应该更明确。 如果我无法直接访问 CVS 存储库所在的服务器怎么办？因此我无法直接 grep 具有 CVS 存储库的文件系统。

Answer 1

如果不访问存储库，则无法使用标准 CVS 工具来执行此操作。那里的第三方工具可能会做到这一点（我不知道有一个，尽管 CS-CVS 似乎声明），但要以编程方式执行此操作，您必须对所有相关文件执行 CVS 日志，然后在日志中检索和搜索 cvs 报告的每个版本（cvs log 是一个命令CVS 中的行选项显示任何文件的修订历史记录，但不显示内容）。

Answer 2

这是我最近在无法访问服务器的情况下使用的。那个时候好像有用了。从工作副本内部调用它，并在 PATH 中使用 cvs。请注意，这不会搜索提交消息，但您可以简单地 grep 'cvs log' 来搜索。

#!/usr/bin/perl

# Searches CVS diffs and first revisions behind the current working
# directory for an expression (perlre syntax).

# Synopsis: cvsgrep [-n] <search-expression> [<file_1> ... <file_n>]

# -n means that contents of matching files should not be printed to stdout.

use Getopt::Std;

my %options=();
getopts("n",\%options);
my $no_content_dump=$options{"n"};

my $search_term=shift
    or die "Error: usage is: cvsgrep [-n] <search-expression>".
    " [<file_1> ... <file_n>]";

sub quote_fn
{
    my $fn=shift;
    $fn =~ s/\'/\'\"\'\"\'/g;
    "'".$fn."'";
}

my $args_str;
while(@ARGV)
{
    my $arg=shift;
    $args_str.=' ' if $args_str;
    $args_str.="e_fn($arg);
}

print 
    "Searching for term: $search_term",
    ($args_str?" in: $args_str":""),
    "\n";

open CVSLOGH,"cvs log -N $args_str|" or die "Cannot execute cvs log: $!";

my @files_revisions=();

my $cur_file;
my $cur_revision;

while(<CVSLOGH>)
{
    chop;
    if(/^Working file\:\s*(.*)$/)
    {
        $cur_file=$1;
        $cur_revision='';
    }
    elsif(/^revision\s+(.*)$/)
    {
        $cur_revision=$1;
    }
    elsif((/^\=\=\=\=/ || /^\-\-\-\-/) && $cur_revision)
    {
        push @files_revisions,{file=>$cur_file,rev=>$cur_revision};
    }
}

close CVSLOGH;

my $matchcount=0;
my $count=0;
my $progress_msg="Scanned %d out of %d commit(s)\r";
my $erase_ln=(" " x (length($progress_msg)+20)) . "\r";

foreach my $file_revision(@files_revisions)
{
    printf($progress_msg,$count++,scalar(@files_revisions));

    my($file,$rev) = ($file_revision->{file},$file_revision->{rev});

    $rev =~ /^(.*\.)([0-9]+)/;
    my $revbase=$1;
    my $revlastdigit=$2;
    my $rev1=$revbase.($revlastdigit - 1);
    my $diffcommand = "cvs diff -N -r $rev1 -r $rev "."e_fn($file);
    open CVSDIFFH,"$diffcommand|" or die "Cannot execute cvs diff: $!";

    my $diffresult;
    while(<CVSDIFFH>)
    {
        if(/^[\<\>]/)
        {
            s/^.//;
            $diffresult.=$_;
        }
    }
    close CVSDIFFH;

    if($diffresult =~ /$search_term/s)
    {
        print "${erase_ln}FOUND: in diff for $file $rev1:$rev\n";
        $matchcount++;
        system($diffcommand) unless $no_content_dump;
    }
}

print "${erase_ln}Done ($matchcount match(es)).\n";

Answer 3

这取决于您要寻找什么。 CVS 版本文件以纯文本形式包含对该文件进行的所有编辑。因此，如果您只是查找包含特定单词的所有文件，请在存储库上执行递归 grep。

如果您要查找包含这些单词的特定版本，那么您将必须从存储库中提取版本，这是昂贵的。但是，如果您可以通过 grep 存储库来限制文件集，那么情况还不错。