如何更新循环中 SELECT 返回的行？

Question

我对 SQL SELECT 语句返回的行有一个循环，并且在对行数据进行一些处理后，有时想要更新该行的值。循环体中的处理并不简单，我无法用 SQL 编写它。当我尝试对所选行执行 UPDATE 时，出现错误（在 Perl 的 DBD::SQLite::st 执行失败：数据库表被锁定下）。有没有一种可读、高效且可移植的方式来实现我想要做的事情？如果做不到这一点，是否有 DBD 或 SQLite 特定的方法可以做到这一点？

显然，我可以将更新推送到单独的数据结构中并在循环后执行它们，但我讨厌代码的处理方式。

如果您有兴趣，这里是相应的 Perl 代码。

my $q = $dbh->prepare(q{
  SELECT id, confLoc FROM Confs WHERE confLocId ISNULL});
$q->execute or die;
my $u = $dbh->prepare(q{
  UPDATE Confs SET confLocId = ? WHERE id = ?});
while (my $r = $q->fetchrow_hashref) {
    next unless ($r->{confLoc} =~ m/something-hairy/);
    next unless ($locId = unique_name_state($1, $2));
    $u->execute($locId, $r->{id}) or die;
}

Answer 1

暂时启用 AutoCommit：

sqlite> .header on
sqlite> select * from test;
field
one
two

#!/usr/bin/perl

use strict;
use warnings;

use DBI;

my $dbh = DBI->connect('dbi:SQLite:test.db', undef, undef,
    { RaiseError => 1, AutoCommit => 0}
);

test_select_with_update($dbh);

sub test_select_with_update {
    my ($dbh) = @_;
    local $dbh->{AutoCommit} = 1;
    my $q = $dbh->prepare(q{SELECT field FROM test});
    my $u = $dbh->prepare(q{UPDATE test SET field = ? WHERE field = ?});
    $q->execute or die;
    while ( my $r = $q->fetchrow_hashref ) {
        if ( (my $f = $r->{field}) eq 'one') {
            $u->execute('1', $f) or die;
        }
    }
}

代码运行后：

sqlite> .header on
sqlite> select * from test;
field
1
two

Answer 2

您的问题是，当您处于获取循环时，您使用相同的数据库处理程序来执行更新。

因此，让数据库处理程序的另一个实例来执行更新：

my $dbh = DBI->connect(...);
my $dbhForUpdate = DBI->connect(...) ;

然后在循环中使用 dbhForUpdate：

while(my $row = $sth->fetch()){
   ...
   $dbhForUpdate->do(...) ;
}

无论如何，我不建议这样做，因为您很有可能在数据库级别遇到并发问题。

Answer 3

更多内容是对 Zoidberg 的评论的回答，但是如果您能够切换到像 Perl 那样的 ORM DBIx::Class 然后你发现你可以写这样的东西：

my $rs = $schema->resultset('Confs')->search({ confLocId => undef });

while ( my $data = $rs->next ) {
    next unless $data->confLoc =~ m/(something)-(hairy)/;
    if ( my $locId = unique_name_state( $1, $2 ) ) {
        $data->update({ confLocID => $locid });
    }
}

如果 DBIx::Class 没有吸引你的兴趣，那么 CPAN 就像Fey：例如 :ORM 和 Rose::DB 。