在 F# 中调用 Seq.skip 和 Seq.take

Question

let aBunch = 1000
let offset = 0

let getIt offset =
  MyIEnumerable
  |> Seq.skip aBunch * offset
  |> Seq.take aBunch
  |> Seq.iter ( .. some processing ...)

使用不同的偏移量调用 getIt() 最终会给我一个“无效操作”异常，并附有“输入序列元素不足”的附加信息，

我试图理解为什么，因为 Seq.Skip 和 Seq.take 都不会根据情况生成异常到在线文档 FSharp Collections

版本：(Visual Studio 2010) Beta 1

Answer 1

这是使用内置函数的稍短的“skipSafe”实现：

module Seq =
    let skipSafe num = 
        Seq.zip (Seq.initInfinite id)
        >> Seq.skipWhile (fun (i, _) -> i < num)
        >> Seq.map snd

或者，如果您希望直接将其内联到当前管道中，请替换

|> Seq.skip num

为

|> Seq.zip (Seq.initInfinite id)
|> Seq.skipWhile (fun (i, _) -> i < num)
|> Seq.map snd

Answer 2

module Seq = 
    let trySkip count source  =
        source |> Seq.indexed |> Seq.filter(fst >> (<=) count) |> Seq.map snd

Answer 3

对于无异常的 skip，您可以将自己的版本添加到 Seq 模块，如下所示：

module Seq =
    let skipSafe (num: int) (source: seq<'a>) : seq<'a> =
        seq {
            use e = source.GetEnumerator()
            let idx = ref 0
            let loop = ref true
            while !idx < num && !loop do
                if not(e.MoveNext()) then
                    loop := false
                idx := !idx + 1

            while e.MoveNext() do
                yield e.Current 
        }

与 Seq.truncate 结合（这是无异常的 Seq.take 等效 - 它将需要尽可能多的可用项目而不引发异常）。

[1..10] 
|> Seq.skipSafe 20
|> Seq.truncate 5

(* returns empty seq *)

Answer 4

我知道这是一个老问题，但如果有人像我一样在搜索中遇到这个问题：

您可以使用 Seq.truncate 如果您最多需要 n 个项目。 如果可用的项目少于 n 个，它不会抛出异常。

Answer 5

如果使用大于序列的值调用，Seq.skip 和 Seq.take 都会抛出此异常。 你可以查看Seq.fs中的源代码来了解原因：

let skip count (sequence: seq<_>) =
    { use e = sequence.GetEnumerator() 
      let latest = ref (Unchecked.defaultof<_>)
      let ok = ref false
      for i in 1 .. count do
          if not (e.MoveNext()) then 
              raise <| System.InvalidOperationException "the input sequence had insufficient elements" 
      while e.MoveNext() do
          yield e.Current }

let take count (sequence : seq<'T>)    = 
    if count < 0 then invalidArg "count" "the number of elements to take may not be negative"
    (* Note: don't create or dispose any IEnumerable if n = 0 *)
    if count = 0 then empty else  
    { use e = sequence.GetEnumerator() 
      for i in 0 .. count - 1 do
          if not (e.MoveNext()) then
              raise <| System.InvalidOperationException "the input sequence had insufficient elements" 
          yield e.Current }

Answer 6

对于 skip，您可以通过委托给 LINQ 的 Skip 轻松定义一个具有（大概）最佳性能的简单 skipSafe：

open System.Linq

let skipSafe count (source: seq<'a>) = source.Skip(count)

对于 take code>，正如其他答案所说，您可以只使用 Seq.truncate，或者可选地为其别名：

let takeSafe count source = Seq.truncate count source