同一窗体类的不同实例如何使用不同的窗口类样式？

Question

我尝试使用以下技术来启用/禁用窗口的阴影效果：（CreateParams 当然被覆盖。TToolWindow 源自 TForm）。

procedure TToolWindow.CreateParams(var Params: TCreateParams); 
var
  LShadow: boolean;

begin
  inherited;

  if (Win32Platform = VER_PLATFORM_WIN32_NT)
    and ((Win32MajorVersion > 5)
    or ((Win32MajorVersion = 5) and (Win32MinorVersion >= 1))) then //Win XP or higher
      if SystemParametersInfo(SPI_GETDROPSHADOW, 0, @LShadow, 0) then
      begin
        if LShadow and HasShadow then
          Params.WindowClass.Style := Params.WindowClass.Style or CS_DROPSHADOW;
      end;
end;

虽然这对于 TToolWindow 类的第一个实例可以正常工作，但以下实例将保留第一个实例的设置，而不管 HasShadow 的值（这是 TToolWindow 类的已发布属性）如何。

如何在 TToolWindow 的不同实例上具有不同的阴影设置？

TIA

Answer 1

每次创建给定类的第一个实例时，VCL 都会动态注册表单类所需的窗口类。 这就解释了为什么 TToolWindow 的所有辅助实例都具有与第一个实例相同的阴影，而不管 HasShadow 值如何。 您正在创建相同窗口类的窗口，因此它们都具有相同的类样式。

您可以做的是注册两个类，一个带有阴影，另一个没有阴影。 如果类名与先前注册的类不同，VCL 将注册一个新的窗口类。

像这样的事情：

procedure TToolWindow.CreateParams(var Params: TCreateParams); 
var
  LShadow: boolean;
begin
  inherited;

  if (Win32Platform = VER_PLATFORM_WIN32_NT)
    and ((Win32MajorVersion > 5)
    or ((Win32MajorVersion = 5) and (Win32MinorVersion >= 1))) 
  then begin
    //Win XP or higher
    if SystemParametersInfo(SPI_GETDROPSHADOW, 0, @LShadow, 0)
      and LShadow and HasShadow
    then begin
      Params.WindowClass.Style := Params.WindowClass.Style or CS_DROPSHADOW;
      StrLCopy(Params.WinClassName, 'TDelphiToolWindowWithShadow', 63);
    end else begin
      Params.WindowClass.Style := Params.WindowClass.Style and not CS_DROPSHADOW;
      StrLCopy(Params.WinClassName, 'TDelphiToolWindowNoShadow', 63);
    end;
  end;
end;

Answer 2

只是猜测...后续实例是 TToolWindow 的子级吗？ 也许他们继承了父母的风格。

编辑：实际上，我在网上读到，如果你给项目一个 WS_CHILD 样式，它会忽略 CS_DROPSHADOW。 因此，如果其他方法都失败，这可能是解决问题的一种方法。