F# 联合成员的 Enum.GetName 等效项是什么？

Question

我想要为 F# 受歧视的联合成员获取相当于 Enum.GetName 的内容。 调用 ToString() 会得到 TypeName+MemberName，这并不是我想要的。 当然，我可以对它进行子串化，但是它安全吗？ 或者也许有更好的方法？

Answer 1

您需要使用 Microsoft.FSharp.Reflection 命名空间中的类，以便：

open Microsoft.FSharp.Reflection

///Returns the case name of the object with union type 'ty.
let GetUnionCaseName (x:'a) = 
    match FSharpValue.GetUnionFields(x, typeof<'a>) with
    | case, _ -> case.Name  

///Returns the case names of union type 'ty.
let GetUnionCaseNames <'ty> () = 
    FSharpType.GetUnionCases(typeof<'ty>) |> Array.map (fun info -> info.Name)

// Example
type Beverage =
    | Coffee
    | Tea

let t = Tea
> val t : Beverage = Tea

GetUnionCaseName(t)
> val it : string = "Tea"

GetUnionCaseNames<Beverage>()
> val it : string array = [|"Coffee"; "Tea"|]

Answer 2

@DanielAsher 的答案有效，但为了使其更优雅（并且更快？因为其中一种方法缺乏反射），我会这样做：（

type Beverage =
    | Coffee
    | Tea
    static member ToStrings() =
        Microsoft.FSharp.Reflection.FSharpType.GetUnionCases(typeof<Beverage>)
            |> Array.map (fun info -> info.Name)
    override self.ToString() =
        sprintf "%A" self

受到 这个和这个。）

Answer 3

该答案为最佳答案提供了更多信息和解决方案。

我刚刚遇到了一个案例，最佳答案不起作用。 问题是该值位于接口后面，然后我有时会得到案例名称（咖啡或茶），但大多数情况下只有类型名称（饮料）。 我不明白为什么。 我使用的是.NET 5.0。

我将函数更改为此，然后它在我的接口 DU 上按预期工作，始终为我提供案例名称。

open FSharp.Reflection

let GetUnionCaseName (x: obj) =
    match FSharpValue.GetUnionFields(x, x.GetType()) with
    | case, _ -> case.Name

我知道这与此处的其他答案类似，但这不是成员函数，因此我想应该适用于任何 DU，无论是否位于接口后面。 我还没有测试过如果在非 DU 类型上使用会发生什么。

type IMessage = interface end

type Beverage = Coffee | Tea

type Car =
    | Tesla of model:string
    | Ford
    interface IMessage
    
type MySingleCase = MySingleCase of string
type SingleCase2 = SingleCase2 of string interface IMessage

let m1: Beverage = Coffee
let m2: IMessage = (Tesla "Model 3") :> IMessage
let m3 = MySingleCase "x"
let m4 = SingleCase2 "x" :> IMessage

printfn "%s" (GetUnionCaseName m1) // Coffee
printfn "%s" (GetUnionCaseName m2) // Tesla
printfn "%s" (GetUnionCaseName m3) // MySingleCase
printfn "%s" (GetUnionCaseName m4) // SingleCase2

Answer 4

我想提出一些更简洁的建议：

open Microsoft.FSharp.Reflection

type Coffee = { Country: string; Intensity: int }

type Beverage =
    | Tea
    | Coffee of Coffee

    member x.GetName() = 
        match FSharpValue.GetUnionFields(x, x.GetType()) with
        | (case, _) -> case.Name  

当 union case 很简单时，GetName() 可能会带来与 ToString() 相同的结果：

> let tea = Tea
val tea : Beverage = Tea

> tea.GetName()
val it : string = "Tea"

> tea.ToString()
val it : string = "Tea"

但是，如果 union case 更花哨，会有区别：。

> let coffee = Coffee ({ Country = "Kenya"; Intensity = 42 })
val coffee : Beverage = Coffee {Country = "Kenya"; Intensity = 42;}

> coffee.GetName()
val it : string = "Coffee"

> coffee.ToString()
val it : string = "Coffee {Country = "Kenya";        Intensity = 42;}"