如何使用 Perl 和 Moose 编写工厂代码？

Question

是否有更简单或更好（=>更易于维护）的方法来使用 Perl 和 Moose< /a> 根据传入数据实例化类？

以下代码是我正在处理的项目中的精简示例。

package FooBar;
use Moose;
has 'SUBCLASS' =>('isa'=>'Str',required=>'1',is=>'ro');
has 'MSG' =>('isa'=>'Str',required=>'1',is=>'ro');

sub BUILD {
      my $self = shift;
      my ($a)=@_;
      bless($self,$a->{SUBCLASS})
}
sub Hi {
   my $self=shift;
   print "Hi, I'm a " . ref($self)  ." and I say [". $self->MSG()."]\n";
}

package Foo;
use Moose;
extends ("FooBar");

package Bar;
use Moose;
extends ("FooBar");

package main;
use strict;
use warnings;

for my $line (<DATA>) {
   my ($case,$msg)=split(/[\n\r,]\s*/,$line);
   FooBar->new(SUBCLASS=>$case,MSG=>$msg)->Hi();
}

__DATA__
Foo, First Case
Bar, Second Case

编辑：令我震惊的是，这几乎就是您致电 DBI 时发生的情况。 根据您传递的参数，它将使用完全不同的代码，同时保持（大部分）一致的接口

Answer 1

恶心。 Stevan 有一个非常令人信服的论点，即 new 应该始终只
返回类的实例。 其他任何事情都会让新人感到困惑
系统。

你可能想看一下
MooseX::AbstractFactory。
如果这对您不起作用：

package FooBar;
use Moose;

has [qw(SUBCLASS MSG)] => ( is => 'ro', required => 1);

sub create_instance {
    return $self->package->new(message => $self->msg);
}

package FooBar::Object;
use Moose;

has msg => ( is => 'ro', required => 1);

sub Hi {
   my $self = shift;
   print "Hi, I'm a " . ref($self)  ." and I say [". $self->MSG()."]\n";
}

package Foo;
use Moose;
extends qw(FooBar::Object);

package Bar;
use Moose;
extends qw(FooBar::Object);


package main;
or my $line (<DATA>) {
   my ($case,$msg)=split(/[\n\r,]\s*/,$line);
   FooBar->new(SUBCLASS=>$case,MSG=>$msg)->create_instance->Hi
}

__DATA__
Foo, First Case
Bar, Second Case

当然，还有许多其他方法可以在 Moose 中实现相同的概念。 如果不知道您的域问题的具体情况，很难判断 MooseX::Traits 不会更好：

package Foo;
use Moose;
with qw(MooseX::Traits);

package Bar;
use Moose;
with qw(MooseX::Traits);

package Messaging;
use Moose::Role;

has msg => ( is => 'ro', required => 1);

sub Hi {
   my $self = shift;
   print "Hi, I'm a " . ref($self)  ." and I say [". $self->MSG()."]\n";
}

package main;
use strict;
Foo->with_traits('Messaging')->new( msg => 'First Case')->Hi;

这大致就是另一张海报关于使用基于角色的解决方案的意思。

Answer 2

您可以简单地这样做：

$case->new( MSG => $msg )->Hi();

是否更容易或更好由您决定。

Answer 3

只是对一些答案的注释：

在 BUILD 中或 MOP 内部之外的任何地方调用 bless 总是不可接受的。 （如果你一定要反驳，有 Class::MOP::Class->rebless_instance！）

我同意不允许 new 返回实例以外的任何内容的建议__PACKAGE__。 如果您想要一个创建某物实例的方法，请将其命名为其他名称。 示例：

class Message {
   method new_from_string(Str $msg){
       my ($foo, $bar, $baz) = ($msg =~ /<...>/); # blah blah blah
       my $class = "Message::${foo}::$baz";
       Class::MOP::load_class($class);
       return $class->new( bar => $msg );
   }
}

然后，当您想要创建文字消息时：

Message->new( whatever => 'you want' );

当您想要解析字符串并返回正确的消息子类时：

Message->new_from_string( 'OH::Hello!' );

最后，如果创建 Message 实例没有意义，那么它不应该成为一个班级。 应该是一个角色。

当然，您可以使用其他对象来构建。 例如，只需确保另一个对象仅负责理解字符串格式，而不是消息内部结构：

class MessageString {
    has 'string' => ( initarg => 'string', reader => 'message_as_string' );

    method new_from_string(ClassName $class: Str $string) {
        return $class->new( string => $string );
    }

    method as_message_object {
        # <parse>
        return Message::Type->new( params => 'go here', ... );
    }
}

role Message { ... }
class Message::Type with Message { ... }

现在您不再关心让某些“超类”负责构建“子类”，我认为这是更好的设计。 （记住，MessageString 对执行“Message”的类没有特殊的权力。这是这里的关键；它只负责理解字符串化消息。）

无论如何，现在您只需：（

my $data =  <>; # Yup, I called it $data.  Sorry, Andy Lester.
my $parsed = MessageString->new_from_string( $data );
my $message = $parsed->as_message_object;
$message->interact_with

您知道“MVC”吗？这很相似。 ）

Answer 4

只需使用另一个工厂对象来构造该类的对象即可。

更简单、更灵活、更可靠等


my $factory = Factory->new( ... 工厂参数 ... );

my $object = $factory->new_object( ... 各种参数 ... );


其中 new_object 可以解析参数并根据 $factory 内部的数据和这些参数中的数据做出决策。

当您发现下一步需要相互依赖的对象时，请寻找控制反转框架。

Answer 5

好吧，当调用 BUILD 时，该对象已经创建了，所以我想说，

sub BUILD {
      my $self = shift;
      return bless $self, $self->SUBCLASS;
}

您可能总是希望从基于继承的模型切换到基于角色的模型，在该模型中创建所需的对象（而不是传递类进入工厂类），然后应用公共角色。