如何根据变量调用命名模板？

Question

我不知道是否可能，但我想知道如何做到这一点...

假设我们有以下 XSL：

<xsl:template name="foo">
  Bla bla bla
</xsl:template>
...
<xsl:template name="bar">
  Bla bla bla
</xsl:template>
...
<xsl:template match="/">
  <xsl:if test="$templateName='foo'">
    <xsl:call-template name="foo"/>
  </xsl:if>
  <xsl:if test="$templateName='bar'">
    <xsl:call-template name="bar"/>
  </xsl:if>
</xsl:template>

是否可以更改 XSL 以读取类似...

<xsl:template match="/">
  <xsl:call-template name="$templateName"/>
</xsl:template>

Answer 1

这不可能完全像您所描述的那样，但是如果您希望能够在运行时根据您在其他地方设置的某个值来选择模板，那么有一个技巧可以做到这一点。 这个想法是让您的命名模板也以不同的模式匹配具有相应名称的节点（这样它就不会扰乱您的正常转换），然后进行匹配。 例如：

<xsl:stylesheet ... xmlns:t="urn:templates">

  <!-- Any compliant XSLT processor must allow and ignore any elements 
       not from XSLT namespace that are immediate children of root element -->
  <t:templates>
    <t:foo/>
    <t:bar/>
  </t:templates>

  <!-- document('') is the executing XSLT stylesheet -->     
  <xsl:variable name="templates" select="document('')//t:templates" />

  <xsl:template name="foo" match="t:foo" mode="call-template">
    Bla bla bla
  </xsl:template>

  <xsl:template name="bar" match="t:foo" mode="call-template">
    Bla bla bla
  </xsl:template>

  <xsl:template match="/">
    <xsl:variable name="template-name" select="..." />
    <xsl:apply-templates select="$templates/t:*[local-name() = $template-name]"
                         mode="call-template"/>
  </xsl:template>

请注意，您可以在 中使用 ，这样您就可以用它做所有您可以做的事情使用普通的 即可。

另外，上面的代码比您可能需要的要长一些，因为它试图避免使用任何 XSLT 扩展。 如果您的处理器支持 exslt:node-set()，那么您可以直接使用 生成节点，并使用 node-set( ) 将生成的树片段转换为普通节点以进行匹配，而不需要 document('') hack。

有关详细信息，请参阅 FXSL - 它是 XSLT 的函数式编程库，就是基于这个概念。

Answer 2

不，这是不可能不是直接可能的。 调用约定是：

<xsl:call-template name="QName" />

其中 QName 定义为：

QName ::= PrefixedName | UnprefixedName

PrefixedName   ::= Prefix ':' LocalPart
UnprefixedName ::= LocalPart

Prefix         ::= NCName
LocalPart      ::= NCName

基本上这可以归结为“只有字符，没有表情”。 正如其他答案所强调的那样，实际上有一些方法可以做等效的事情，但直接的方法/天真的方法行不通。

Answer 3

供任何人将来参考：

这是一个基于 Pavel Minaev 答案的工作示例。 我没有原创的想法。 ;-) 我将其切换为使用 msxml:node-set 正如他所描述的（或多或少），以便它可以在 .NET 中工作。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" version="1.0">
    <xsl:variable name="templates">
        <templates>
            <foo />
            <bar />
        </templates>
    </xsl:variable>
    <xsl:template name="foo" match="foo" mode="call-template">
        <FooElement />
    </xsl:template>
    <xsl:template name="bar" match="bar" mode="call-template">
        <BarElement />
    </xsl:template>
    <xsl:template match="/">
        <Root>
            <xsl:variable name="template-name">bar</xsl:variable> <!-- Change this to foo to get the other template. -->
            <xsl:apply-templates select="msxsl:node-set($templates)/*/*[local-name() = $template-name]" mode="call-template" />
        </Root>
    </xsl:template>
</xsl:stylesheet>

Answer 4

更新：下面的链接已更新为指向 web.archive.org - 不幸的是，IDEALLIANCE 已使所有Exteme Markup Languages会议记录不可用...
在适当的时候，我会为这两篇文章找到一个更永久的位置。

---

这是在 FXSL 中实现的。

对 FXSL 的主要原理有很好的解释。

请参阅以下两篇文章：

“使用 FXSL 库在 XSLT 中进行函数式编程”（适用于 XSLT 1.0），(PDF)，网址为：

http://web.archive.org/web/ 20070710091236/http://www.idealliance.org/papers/extreme/proceedings/xslfo-pdf/2003/Novatchev01/EML2003Novatchev01.pdf

（HTML）位于：

http://conferences.idealliance.org/extreme/html/2003/Novatchev01/EML2003Novatchev01.html

“使用 XSLT 2.0 和 FXSL 进行高阶函数编程”(PDF)，位于：

http://web.archive.org/web/20070222111927/http://www .idealliance.org/papers/extreme/proceedings/xslfo-pdf/2006/Novatchev01/EML2006Novatchev01.pdf

（HTML）位于：
http://conferences.idealliance.org/extreme/html/2006/ Novaatchev01/EML2006Novatchev01.html

使用 FXSL，我已经能够轻松、优雅地解决许多“对于 XSLT 来说不可能”的问题。 此处可以找到很多示例。

Answer 5

我想我或多或少有和你一样的问题。 我有一个“外部”模板，并且想根据运行时设置的某些变量来调用不同的“内部”模板。 我通过谷歌搜索找到了您的问题，以获取动态 的方法。 我通过使用 解决了这个问题，如下所示。

输入 XML（在运行时生成）包含以下内容：

<template name="template_name_1"/>

“外部”模板中的 XSL 具有：

<xsl:apply-templates select="template"/>

（此 apply-templates 中的 select="template" 指的是到输入 XML 中的

最后是“内部”模板，我希望将其作为 name 值的结果包含在内我的 XML 中的 code> 属性看起来像：

<xsl:template match="template[@name='template_name_1']">
    <!-- XSL / XHTML goes here -->
</xsl:template>

（同样，match="template[@name='xyz']" 引用了之前的 select="template"< /code> 并依次到输入 XML 中的

通过这种方式，我可以动态地“调用“模板只需通过我的输入 XML 进行控制。

这可能与您试图解决的问题不同，但我认为它非常接近，并且比本页其他地方提到的 FSXL 解决方案简单得多。

Answer 6

这个怎么样？：

  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:template match="xsl:template[@name='foo']" name="foo">
    Bla bla bla foo
      </xsl:template>

      <xsl:template match="xsl:template[@name='bar']" name="bar">
    Bla bla bla bar
      </xsl:template>

      <xsl:template match="/">
        <xsl:variable name="templateName" select="'bar'"/>
        <xsl:apply-templates select="document('')/*/xsl:template[@name=$templateName]"/>
        <xsl:apply-templates select="document('')/*/xsl:template[@name='foo']"/>
      </xsl:template>

    </xsl:stylesheet>

您可以使用变量来简化模板的“调用”，与之前的贡献中所述类似：

<xsl:variable name="templates" select="document('')/*/xsl:template"/> 

<xsl:apply-templates select="$templates[@name=$templateName]"/>
<xsl:apply-templates select="$templates[@name='foo']"/>

请注意，可以照常使用可选的 。

Answer 7

谢谢@Pavel、@Dimitre 的出色回答。 这是另一个工作示例，基本上回收了 @Pavel 的方法以供将来参考......

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  

  <xsl:variable name="templates">
    <xsl:for-each select="('foo','bar')">
      <xsl:element name="{.}"/>
    </xsl:for-each>
  </xsl:variable>
  
  <xsl:template name="foo" match="foo" mode="call-template">
    Foo foo foo
  </xsl:template>
  
  <xsl:template name="bar" match="bar" mode="call-template">
    Bar bar bar
  </xsl:template>
  
  <xsl:template match="/">
  
    <xsl:for-each select="('bar','foo','foo','bar')">
      <xsl:variable name="template-name" select="." />
      <xsl:apply-templates select="$templates/*[local-name() = $template-name]"  mode="call-template"/>
    </xsl:for-each>
    
    
  </xsl:template>

</xsl:stylesheet>