AS2：如何在通过 MovieClipLoader 加载的 SWF/MovieClip 上使用 addEventListener

Question

我正在尝试加载本地 SWF，然后捕获一些被触发的事件，但我不明白为什么这不起作用。

这是代码

Parent.swf

_mcl = new MovieClipLoader();
_mcl.addListener(this);
_mcl.loadClip("Child.swf", rotator_mc);

function onLoadComplete(clip) {
    clip.addEventListener("initAsLoaded", function() {trace("childLoaded loaded 1")});
}

function onLoadInit(clip) {
    clip.addEventListener("initAsLoaded", function() {trace("childLoaded loaded 2")});
}

Child.swf

import mx.events.EventDispatcher;

function dispatchEvent() {};
function addEventListener() {};
function removeEventListener() {};

EventDispatcher.initialize(this);

trace("Child dispatching: childLoaded");
dispatchEvent({type:"childLoaded", target: this});

现在我希望这能起作用，并且 Parent 会在跟踪中包含“childLoaded catch 2”，但事实并非如此。

有什么办法可以实现我想要做的事情吗？

Answer 1

我注意到的第一件事是，在父级中，您列出了一个名为 initAsLoaded 的事件，但在子级中，您正在调度一个名为 childLoaded 的事件。 监听永远不会发送的事件可能不是一个好主意。

然而，这不是真正的问题，因为修复事件并不能解决问题。 主要问题是 MovieClipLoader 中的 onLoadInit 事件是在执行 child.swf 第一帧的代码之后调度的。 这意味着在 child.swf 中，您将在没有人监听的第一帧上调度一个事件，因为尚未调用 onLoadInit。

要解决此问题，您只能从第二帧及以后开始调度 child.swf 中的事件。

父母第一帧：

var rotator_mc = _root.createEmptyMovieClip("rotator_mc", _root.getNextHighestDepth() );

_mcl = new MovieClipLoader();
_mcl.addListener(this);
_mcl.loadClip("child.swf", rotator_mc);

function onLoadComplete(clip) {
    trace("onLoadComplete " + clip + ", " + clip.addEventListener );
    clip.addEventListener("initAsLoaded", function() {trace("childLoaded loaded 1")});
}

function onLoadInit(clip) {
    trace("onLoadInit " + clip + ", " + clip.addEventListener );
    clip.addEventListener("initAsLoaded", function() {trace("childLoaded loaded 2")});
}

这是我对你父母第一帧的版本。 我必须创建一个空的影片剪辑作为容器，并向事件处理程序添加一些跟踪。

儿童第一帧：

import mx.events.EventDispatcher;

EventDispatcher.initialize( this );

儿童第二帧：

stop();

this.dispatchEvent({type:"initAsLoaded", target: this});

trace("Child dispatching: childLoaded");

希望这有帮助...