AS3 圆角文本字段

Question

有谁知道如何在 AS3 中创建具有可见边框和圆角的动态文本字段？

我想我可能需要创建一个圆形影片剪辑，调整大小并将其放置在文本后面。

我尝试过这个，但我没有看到任何变化。

var styleRound:StyleSheet = new StyleSheet();
styleRound.parseCSS("h4{cornerRadius:10;borderStyle: solid; borderThickness: 1;}");
tf.htmlText = "<h4>" + hotspotData.caption + "</h4>";
tf.styleSheet = styleRound;

Answer 1

以下是ActionScript 3 中 TextField 的可用 CSS 样式的列表< /a>. 抱歉，没有圆角半径。

您可以在 TextField 对象上打开文本字段的边框 边界属性。 但附近没有可用的房产。

我建议您创建一个新组件，并自行将边框添加为 TextField 下方的 Sprite。 就像是：

package
{

import flash.display.Graphics;
import flash.display.Sprite;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;

public class TextBorder extends Sprite
{
    private static const CORNER_RADIUS:int = 5;
    // display objects
    private var background:Sprite;
    private var field:TextField;

    // properties
    private var _text:String;

    public function TextBorder()
    {
        background = new Sprite;
        field = new TextField;
        field.autoSize = TextFieldAutoSize.LEFT;

        addChild(background);
        addChild(field);

        // TESTING:
        text = "Hello World";
    }

    public function set text(newText:String):void
    {
        _text = newText;
        display();
    }

    public function get text():String
    {
        return _text;
    }

    private function display():void
    {
        field.text = _text;

        var g:Graphics = background.graphics;
        g.clear();
        g.lineStyle(0, 0x0);
        g.beginFill(0xFFFFFF);
        g.drawRoundRect(0, 0, field.width, field.height, CORNER_RADIUS);
    }
}

}

Answer 2

我最终在 Flash 中创建了一个圆角矩形并将其导出为自己的类 - hotspotBG。

var hotspotBackground:hotspotBG = new hotspotBG();
hotspotBackground.width = textField.width + 10;
caption.addChild(hotspotBackground);

Answer 3

您无法自行更改文本字段，截至 2014 年，Flash 不允许这样做。

你能做的就是删除背景和边框，
这将使文本字段完全透明，
然后在文本字段后面添加一个图像（矩形工具是最简单的方法），
这样文本字段就位于图像的顶部（z 轴方向），

这可能不是您想到的方式，但它确实有效！

//您正在删除背景和边框
//并用图像替换它们
文本框.背景=假；
textbox.border=false;

Answer 4

可以只使用CSS样式吗？ 比如：

TextInput { 
  borderStyle: solid; 
  borderThickness: 1; 
  cornerRadius: 2; 
}

我还没有测试过这个，但这应该会给你一个圆角。