我可以在 ColdFusion 中按索引获取查询行吗？

Question

我想获取 ColdFusion 查询对象中的特定行而不对其进行循环。

我想做这样的事情：

<cfquery name="QueryName" datasource="ds">
SELECT *
FROM    tablename
</cfquery>

<cfset x = QueryName[5]>

但是它给了我一个错误，说查询不能按“5”进行索引。 我知道这个查询中有超过 5 条记录。

Answer 1

您无法获得 CF <= 10 中的行。您必须获得特定的列。

<cfset x = QueryName.columnName[5]>

然而，距离我发布这个答案已经过去了 8 年。 显然CF11最终实现了这个功能。 请参阅此答案。

Answer 2

现在可以在 Coldfusion 11 中通过 QueryGetRow< 来完成此操作/a>

<cfquery name="myQuery" result="myresult" datasource="artGallery" fetchclientinfo="yes" >
select * from art where ARTID >
<cfqueryparam value="2" cfsqltype="CF_SQL_INTEGER">
</cfquery>

<cfdump var="#myQuery#" >

<cfset data = QueryGetRow(myQuery, 1) >

<cfdump var="#data#" >

Answer 3

我认为有一个更简单的解决方案......
我猜您知道您的列名称，并且只想要这一列或那一列。 那么您不需要将整行放入结构中。 您可以按行号引用查询（记住它是基于 1 而不是 0）。

yourQueryName["yourColumnName"][rowNumber]

<cfoutput>
     #mycontacts["Name"][13]#
     #mycontacts["HomePhone"][13]# 
</cfoutput>

Answer 4

您必须首先将查询转换为结构：

<cfscript>
    function GetQueryRow(query, rowNumber) {
        var i = 0;
        var rowData = StructNew();
        var cols = ListToArray(query.columnList);
        for (i = 1; i lte ArrayLen(cols); i = i + 1) {
            rowData[cols[i]] = query[cols[i]][rowNumber];
        }
        return rowData;
    }
</cfscript>

<cfoutput query="yourQuery">
    <cfset theCurrentRow = GetQueryRow(yourQuery, currentRow)>
    <cfdump var="#theCurrentRow#">
</cfoutput>

希望这能为您指明正确的方向。

Answer 5

我知道每当我谷歌“cfquery 括号符号”时我都会回到这个线程。 这是我编写的一个函数，用于使用括号表示法处理这种情况。 希望这也可以帮助其他人：

<cffunction name="QueryGetRow" access="public" returntype="array" hint="I return the specified row's data as an array in the correct order">
    <cfargument name="query" required="true" type="query" hint="I am the query whose row data you want">
    <cfargument name="rowNumber" required="true" hint="This is the row number of the row whose data you want">

    <cfset returnArray = []>
    <cfset valueArray = []>

    <cfset cList = ListToArray(query.ColumnList)>
    <cfloop from="1" to="#ArrayLen(cList)#" index="i">
        <cfset row = query["#cList[i]#"][rowNumber]>
        <cfset row = REReplace(row, "(,)", " ")>
        <cfset returnArray[i] = row>
        <cfset i++>
    </cfloop>   
    <cfreturn returnArray>
</cffunction>

REReplace 是可选的，我用它来清理逗号，这样如果您以后必须使用它，它就不会搞砸 arrayToList 函数。

Answer 6

我想从查询中提取一行，并保留列名（当然）。 这就是我解决它的方法：

<cffunction name="getQueryRow" returntype="query" output="no">
    <cfargument name="qry" type="query" required="yes">
    <cfargument name="row" type="numeric" required="yes">
    <cfset arguments.qryRow=QueryNew(arguments.qry.columnlist)>
    <cfset QueryAddRow(arguments.qryRow)>
    <cfloop list="#arguments.qry.columnlist#" index="arguments.column">
        <cfset QuerySetCell(arguments.qryRow,arguments.column,Evaluate("arguments.qry.#arguments.column#[arguments.row]"))>
    </cfloop>
    <cfreturn arguments.qryRow>
</cffunction>

Answer 7

前面描述的通过列名和行号获取查询数据的方法（variables.myquery["columnName"][rowNumber]）是正确的，但不方便获取整行查询数据。

我正在运行 Railo 4.1。 这是一个很酷的解决方案。 遗憾的是，这无法按照我们想要的方式直接获取整行数据，但以下方法允许我们通过一些步骤获得我们想要的内容。

当您 serializeJSON(variables.myquery) 时，它会将查询更改为 JSON 格式的 cfml 结构对象，其中包含两项：“Columns”和“Data”。 这两个都是数据数组。 “数据”数组是一个二维数组，先包含行数据，然后包含列数据。

问题是现在我们有一个无法使用的字符串。 然后，如果我们重新序列化它，它不是一个查询，而是上述格式的可用常规结构。

假设我们已经有一个名为“variables.myquery”的查询变量。 然后看下面的代码：

<cfset variables.myqueryobj = deserializeJSON(serializeJSON(variables.myquery)) />

现在，您可以通过以下方式获得二维数组：

<cfset variables.allrowsarray = variables.myqueryobj.data />

通过以下方式获得一个查询行数组：

<cfset variables.allrowsarray = variables.myqueryobj.data[1] />

OR 最后一行：

<cfset variables.allrowsarray = variables.myqueryobj.data[variables.myquery.recordCount] />

您可以通过列顺序编号迭代获得各个列值：

<cfset variables.allrowsarray = variables.myqueryobj.data[1][1] />

现在对于大型查询结果来说，这可能很慢并且可能不明智，但这仍然是一个很酷的解决方案。

Answer 8

查看 queryGetRow 的文档。 它接受一个查询对象和一个行索引，其中第一行的索引为 1（非 0）。这种方式使用的索引必须是正整数。

<cfquery name="QueryName" datasource="ds">
  SELECT *
  FROM tablename
</cfquery>

<!---
    This would retrieve the first record of the query
    and store the record in a struct format in the variable 'x'.
--->
<cfset x = queryGetRow(QueryName, 1) />
<!---
    This is an alternative using the member method form of queryGetRow
--->
<cfset x = QueryName.getRow(1) />