如何在 Erlang 中创建临时文件名？

Question

我需要将数据放入文件中，因为我的其他函数将文件作为输入。

如何在 Erlang 中创建唯一的文件名？

是否存在像unix“tempfile”这样的东西？

Answer 1

您的意思是只生成实际的文件名吗？ 在这种情况下，最安全的方法是混合使用从 now() 获得的数字和计算机的主机名（如果您有多个节点执行相同的操作）。

就像是：

1> {A,B,C}=now().
{1249,304278,322000}
2> N=node().
nonode@nohost
3> lists:flatten(io_lib:format("~p-~p.~p.~p",[N,A,B,C])).
"[email protected]"
4> 

Answer 2

您还可以使用TMP = lib:nonl(os:cmd("mktemp"))。

Answer 3

或者您可以使用

erlang:phash2(make_ref())

来获得快速且简单的唯一标识符。 最多可进行 2^82 次调用，这应该足以满足您的目的。 我发现这比使用节点名称格式化时间戳更容易。

Answer 4

迟到的答案：我刚刚注意到 test_server 模块具有暂存目录支持，值得一看

http://www.erlang.org/doc/man/test_server.html#temp_name-1

Answer 5

我终于遇到了这个问题 - 而且我的用户混合使用 Windows 和 Linux 系统，因此旧的经过验证的 lib:nonl(os:cmd("mktemp"))方法已经不再有效了。

以下是我的处理方法，既使用返回可以使用的文件名的 mktemp/1 函数，也使用返回目录的 mktemp_dir/1 函数（创建后）。

-spec mktemp(Prefix) -> Result
   when Prefix   :: string(),
        Result   :: {ok, TempFile  :: file:filename()}
                  | {error, Reason :: file:posix()}.

mktemp(Prefix) ->
    Rand = integer_to_list(binary:decode_unsigned(crypto:strong_rand_bytes(8)), 36),
    TempPath = filename:basedir(user_cache, Prefix),
    TempFile = filename:join(TempPath, Rand),
    Result1 = filelib:ensure_dir(TempFile),
    Result2 = file:write_file(TempFile, <<>>),
    case {Result1, Result2} of
         {ok, ok}    -> {ok, TempFile};
         {ok, Error} -> Error;
         {Error, _}  -> Error
    end.

目录版本：

-spec mktemp_dir(Prefix) -> Result
   when Prefix  :: string(),
        Result  :: {ok, TempDir   :: file:filename()}
                 | {error, Reason :: file:posix()}.

mktemp_dir(Prefix) ->
    Rand = integer_to_list(binary:decode_unsigned(crypto:strong_rand_bytes(8)), 36),
    TempPath = filename:basedir(user_cache, Prefix),
    TempDir = filename:join(TempPath, Rand),
    Result1 = filelib:ensure_dir(TempDir),
    Result2 = file:make_dir(TempDir),
    case {Result1, Result2} of
         {ok, ok}    -> {ok, TempDir};
         {ok, Error} -> Error;
         {Error, _}  -> Error
    end.

这两者的作用基本上相同：我们获得一个强随机名称作为二进制文件，将其转换为 Base36 字符串，并将其附加到操作系统返回给我们的任何内容作为安全的用户本地临时缓存位置。

当然，在 unix 类型系统上，我们可以只使用 filename:join(["/tmp", Prefix, Rand])，但在 Windows 上 /tmp 不可用这就是重点。

Answer 6

在 OTP 24 中，没有 file:ensure_dir。 所以我做了类似的事情：

对于目录：

mktemp_dir(Prefix) ->
    Rand = integer_to_list(binary:decode_unsigned(crypto:strong_rand_bytes(8)), 36),
    TempDir = filename:basedir(user_cache, Prefix),
    []= os:cmd("mkdir " ++ "\"" ++ TempDir ++ "\""),
    {ok, _} = file:list_dir(TempDir),
    TempDir.

对于文件：

mktemp(Prefix) ->
    Rand = integer_to_list(binary:decode_unsigned(crypto:strong_rand_bytes(8)), 36),
    TempDir = filename:basedir(user_cache, Prefix),
    TempFile = filename:join(TempDir, Rand),
    []= os:cmd("mkdir " ++ "\"" ++ TempDir ++ "\""),
    {ok, _} = file:list_dir(TempDir),
    Result = file:write_file(TempFile, <<>>),
    case {Result} of
         {ok}    -> {ok, TempFile};
         {Error}  -> Error
    end.