如何制作 PNG 资源？

Question

我有一个表单，上面有一个大的 TImage 作为背景。 问题是，它作为位图直接存储在 DFM 中，大约占用 3 MB。 原始 PNG 文件约为 250K。 我想尝试通过将 PNG 嵌入资源中来减少膨胀，然后让表单在 OnCreate 期间加载它。 现在我可以做到这一点，因为 Delphi 2009 包含 PNG 支持，但我不太知道如何构建包含 PNG 的资源文件。 有人知道这是怎么做到的吗？

Answer 1

示例文本文件（名为 myres.rc）：

MYPNG RCDATA mypng.png

添加到项目：

{$R 'myres.res' 'myres.rc'}

运行时加载示例：

uses
  PngImage;

var
  Png: TPngImage;
begin
  Png := TPngImage.Create;
  try
    Png.LoadFromResourceName(HInstance, 'MYPNG');
    Image1.Picture.Graphic := Png; // Image1: TImage on the form
  finally
    Png.Free;
  end;
end;

Answer 2

对于那些使用 C++ Builder 的人来说，此代码对我有用：

在 ResourceTest.rc 文件中

IMG_BMP BITMAP "Ressources\\myimage.bmp";
IMG_PNG RCDATA "Ressources\\myimage.png";

在 ResourceTest.rh 文件中

#ifndef ResourceTestRH
#define ResourceTestRH

#define IMG_BMP "IMG_BMP"
#define IMG_PNG "IMG_PNG"

#endif

在 ResourceTest.cpp 文件中

#include "pngimage.hpp"

// Loading bmp image from resource
Graphics::TBitmap *bmpImage = new Graphics::TBitmap();
bmpImage->LoadFromResourceName((int)HInstance, IMG_BMP);

// Loading png image from resource
TPngImage *pngImage = new TPngImage();
pngImage->LoadFromResourceName((int)HInstance, IMG_PNG);

Answer 3

如果您使用的是 Delphi 2009，TImage 应该将您的 PNG 文件作为 PNG 存储到 DFM 文件中。 DFM 会更大，因为 TImage 对象的 Picture.Data 属性的二进制内容在 DFM 中编码为十六进制文本。 但是当 DFM 被编译到 EXE 中时，它被编译成二进制资源。 然后，您的图像应该在表单的 RCDATA 资源中占用与将 PNG 存储在其自己的 RCDATA 资源中相同的空间。

我刚刚通过打开我自己的 Delphi 2009 DFM 文件之一进行了测试，该文件具有 TImage 组件，其中包含在设计时在文本编辑器中加载的 PNG 图像，复制 Picture.Data 属性的内容并将其粘贴到十六进制编辑器中。 十六进制编辑器向我显示 Picture.Data 属性存储了一个以 10 字节为前缀的实际 PNG 文件。 第一个字节是 $09，接下来的 9 个字节拼写为 TPngImage。 如果我删除这 10 个字节并将文件保存在十六进制编辑器中，我会得到一个正确的 PNG 文件。

因此，如果您使用的是 Delphi 2009，只需在设计时将 PNG 图像加载到 TImage 组件中即可。

Answer 4

使用 Resource Hacker 时，PNG 图像会添加“PNG”< em>ResType 而不是常见的 RT_RCDATA。

TPngImage Class Helper 为这个问题提供了一个简单的解决方案：

Type
  TPngImageHelper = Class Helper For Vcl.Imaging.pngimage.TPngImage
    Procedure LoadFromRHResourceName(Instance: HInst; Const Name: String);
  End;

...

Procedure TPngImageHelper.LoadFromRHResourceName(Instance: HInst; Const Name: String);
Var
  rs: TResourceStream;
Begin
  rs := TResourceStream.Create(Instance, PChar(Name), 'PNG');
  Try
    LoadFromStream(rs);
  Finally
    rs.Free;
  End;
End;

通过简单的使用：

var
  pngInfo: TPngImage;
begin
  pngInfo := TPngImage.Create;
  try
    pngInfo.LoadFromRHResourceName(HInstance, 'MY_IMAGE.PNG');
    Image1.Picture.Graphic:= pngInfo;
  finally
    pngInfo.Free;
  end;
end;