如何在 Perl 中运行子命令正确导入环境？

Question

在从子命令导入环境时，我想将从 bash 脚本导出的所有环境变量添加到哈希中。 当program运行时，它将设置一些变量并导出它们。 我想将这些变量保存在 Perl 脚本中供以后使用。 但是我不想采用子命令中定义的 bash 函数。 目前，我有一个类似的问题：

foreach (`program; env`)
{
    next if /^\(\)/;
    my ($a, $b) = split("=", $_);
    if( /^(\w+)=(.*)$/ ) {
        $hash{$1} = $2;    
    }
}

有更好的方法吗？ 我不确定匹配初始 () 是否安全。 处理环境变量中的换行符的奖励积分，我现在只是闭上眼睛。

Answer 1

你想要的就在那里： Shell-EnvImporter

示例：

  use Shell::EnvImporter;

  # Import environment variables exported from a shell script
  my $sourcer  = Shell::EnvImporter->new(
                   file => $filename,
                 );


  my $result = $sourcer->run() or die "Run failed: $@";

Answer 2

我假设 program 执行后的环境变量与传递给它的环境不同（您可以在 %ENV 中找到，如 jeje的回答。

我是我对 bash 一点也不了解，所以我只会解决有关解析 env 输出的问题部分。

#!/usr/bin/perl

use strict;
use warnings;

use autodie qw( open close );

$ENV{WACKO} = "test\nstring\nwith\nnewlines\n\n";

my %SUBENV;

open my $env_h, '-|', 'env';

my $var;

while ( my $line = <$env_h> ) {
    chomp $line;
    if ( my ($this_var, $this_val) = $line =~ /^([^=]+)=(.+)$/ ) {
        if ( $this_val =~ /^\Q()\E/ ) {
            $var = q{};
            next;
        }
        $var = $this_var;
        $SUBENV{ $var } = $this_val;
    }
    elsif ( $var ) {
        $SUBENV{ $var } .= "\n$line";
    }
}

use Data::Dumper;
print Dumper \%SUBENV;

Answer 3

这对于获取所有环境变量应该没问题。

for(`program; env`){
  if( /^([^=]+)=(.*)$/ ) {
    $hash{$1} = $2;    
  }
}

如果您想从头开始，这可能会更好。

for(`env -i bash -c "program; env"`){
  next if /\(\)/;
  if( /^([^=]+)=(.*)$/ ) {
    $hash{$1} = $2;    
  }
}

env -i 使其子命令从头开始。

它使用 -c 参数调用 bash 以及要运行的命令。 我们需要这样做，因为否则第二个 env 将无法从程序中获取环境变量。