如何强制从子级到父级调整大小

Question

我有一个类似页面的弹性应用程序。 在我的主应用程序中，有一个显示所有页面的支架（画布）。 问题在于，加载到支架内的组件比主应用程序启动时支架内的组件要大。 支架高度设置为 100%，但当我在他体内加载比他自己更大的组件时，他仍然会出现滚动条。

我怎么解决这个问题？ 如果它无法解决，如果我使用视图堆栈它会正常工作吗？

--更新---

持有者看起来像这样：

<mx:canvas height="100%">
</canvas>

但应用程序的末尾低了 500 像素，因此画布高度为 500 像素高。 现在，我将一个新子项放入 1000 像素高的支架内。 现在支架高度应为 1000 像素高

Answer 1

在将组件添加到主画布之前，检查子组件的大小，看看它是否比父组件大。 如果是，那么您可以在对象上使用scaleX和scaleY将其缩小以适合您定义的区域。

您在问题中声明的是任何弹性容器的默认行为...将更大的东西放入其中，您将获得滚动条。 要消除滚动条，请使用：

horizontalScrollPolicy="off"
verticalScrollPolicy="off

编辑：

在 tabNavigator 或 viewStack 上使用“resizeToContent”...或者您可以将父容器的宽度绑定到当前子容器的宽度。

Answer 2

这是我正在使用的一些代码，用于自动调整画布大小

// 另存为 AutoResizeCanvas.as

package
{
    import mx.containers.Canvas;
    import mx.core.Container;
    import mx.core.UIComponent;

    public class AutoResizeCanvas extends Canvas
    {
        public function AutoResizeCanvas()
        {
            super();
        }

        override protected function measure():void
        {
            super.measure();
            var nh:int = 0;
            var nw:int = 0;
            for( var n:int = 0; n< this.numChildren; n++)
            {
                var c:UIComponent = this.getChildAt( n) as UIComponent;
                if( c is Container)
                {
                    var cc:Container= c as Container;
                    nh += /*cc.viewMetricsAndPadding.top + */cc.viewMetricsAndPadding.bottom + c.height;
                    nw = Math.max( nw, cc.viewMetricsAndPadding.left + cc.viewMetricsAndPadding.right + c.width);
                } 
                else
                {
                    nh += c.height;
                    nw = Math.max( c.width, nw);
                }
            }
            this.measuredWidth = nw;
            this.measuredHeight = nh;
        }
    }
}

// 测试代码，粘贴到项目的主 mxml 中

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" xmlns:local="*">
    <mx:Script>
        <![CDATA[
            import mx.containers.Panel;
            import mx.containers.HBox;
            private function addOne():void
            {
                var hb:Panel = new Panel();
                hb.height = 100;
                hb.width = 100;
                hb.y = rc.numChildren * 110;
                rc.addChild( hb);
            }
        ]]>
    </mx:Script>
    <local:AutoResizeCanvas id="rc" verticalScrollPolicy="off" borderStyle="solid"/>
    <mx:Button x="497" y="10" label="Add HBox" click="addOne()"/>
</mx:Application>