使用 WPF 的 F# 中的 INotifyPropertyChanged 和 INotifyCollectionChanged

Question

我有一组示例信息，这些信息在后台线程中不断刷新。

目前，我不断使用 DispatcherTimer 将此数组分配给数据网格的 ItemsSource 属性。 这是可行的，但它会重置任何视觉位置，例如，如果用户将光标放在数据网格的中间，执行计时器将撤消该位置。

是否可以使用 INotifyPropertyChanged 或 INotifyCollectionChanged 事件来防止此类情况发生？ 如果是这样，这在 F# 中如何工作？

我想每次数组更新时我都必须执行一些通知数据网格的函数。 数组的更新不在STAThread部分。

我正在使用包含 WPF 数据网格的最新 WPF 工具包运行 VS2010。

Answer 1

您可以使用 ObservableCollection 来为您实现 INotifyCollectionChanged。 F# 看起来像这样：

open System
open System.Collections.ObjectModel
open System.Windows
open System.Windows.Controls
open System.Windows.Threading

[<EntryPoint; STAThread>]
let Main args =

    let data    = ObservableCollection [0 .. 9]
    let list    = ListBox(ItemsSource = data)    
    let win     = Window(Content = list, Visibility = Visibility.Visible)    
    let rnd     = Random()

    let callback = 
        EventHandler(fun sender args -> 
            let idx = rnd.Next(0, 10)
            data.[idx] <- rnd.Next(0, 10) 
            )

    let ts  = TimeSpan(1000000L)
    let dp  = DispatcherPriority.Send
    let cd  = Dispatcher.CurrentDispatcher   

    let timer   = DispatcherTimer(ts, dp, callback, cd) in timer.Start()    
    let app     = Application() in app.Run(win)

不幸的是 Reflector 显示 System.Windows.Controls.ItemsControl.OnItemCollectionChanged 方法在调用时会删除选择，因此您可能需要解决此默认行为。

您还可以像这样实现 INotifyPropertyChanged：

open System.ComponentModel

type MyObservable() =

    let mutable propval = 0.0
    let evt             = Event<_,_>()   

    interface INotifyPropertyChanged with

        [<CLIEvent>]
        member this.PropertyChanged = evt.Publish

    member this.MyProperty

        with get()  = propval
        and  set(v) = propval <- v
                      evt.Trigger(this, PropertyChangedEventArgs("MyProperty"))

实现 INotifyCollectionChanged 的​​工作原理类似。

祝你好运，

丹尼

Answer 2

ObservableCollection 可以工作，但不幸的是存在问题。

由于 ObservableCollection 仅在 STAThread 中修改时才起作用，因此我必须使用调度程序并基本上重写或至少检查整个数组，因为我无法判断哪些条目已更改或未更改。

可能的一件事是使用 F# 邮箱。 后台线程可以放置更改消息，这些消息可以由 STAThread 中的调度程序拾取。 该解决方案还消除了同步的需要。

这看起来是不是太过分了？ 以前有人这样做过吗？ 还有其他解决方案吗？