Haskell：单子 takeWhile？

Question

我有一些用 C 编写的函数，我从 Haskell 调用它们。 这些函数返回 IO (CInt)。 有时我想运行所有函数，无论它们返回什么，这很容易。 为了示例代码，这是当前正在发生的事情的总体思路：

Prelude> let f x = print x >> return x
Prelude> mapM_ f [0..5]
0
1
2
3
4
5
Prelude>

我得到了我想要的副作用，并且我不关心结果。 但现在我需要在第一个项目未返回我想要的结果后立即停止执行。 假设返回值 4 或更高需要停止执行 - 那么我想要做的是这样的：

Prelude> takeWhile (<4) $ mapM f [0..5]

这给了我这个错误：

<interactive>:1:22:
    Couldn't match expected type `[b]' against inferred type `IO a'
    In the first argument of `mapM', namely `f'
    In the second argument of `($)', namely `mapM f ([0 .. 5])'
    In the expression: takeWhile (< 4) $ mapM f ([0 .. 5])

这对我来说是有意义的 - 结果仍然包含在IO monad，我不能只比较 IO monad 中包含的两个值。 我知道这正是 monad 的目的——将结果链接在一起并在满足特定条件时丢弃操作——但是在这种情况下有没有一种简单的方法来“包装”IO monad 以停止根据条件执行链我的选择，而不编写 MonadPlus 的实例？

为了 takeWhile 的目的，我可以直接从 f 中“取消”值吗？

这是函子适合的解决方案吗？ 函子还没有与我“合拍”，但我有这样的印象：这可能是使用它们的好情况。

---

Update:

@sth 有最接近我想要的答案 - 事实上，这几乎正是我想要的，但我仍然想看看是否有一个非显式递归的标准解决方案——毕竟这是 Haskell！ 回顾我如何措辞我的问题，现在我发现我对自己想要的行为还不够清楚。

我上面用于示例的 f 函数只是一个示例。 真正的函数是用 C 编写的，并且专门用于其副作用。 我无法使用 @Tom 的 mapM_ f (takeWhile (<4) [0..5]) 的建议，因为我不知道任何输入在执行之前是否会真正导致成功或失败。

我实际上也不关心返回的列表——我只想调用 C 函数，直到列表耗尽或第一个 C 函数返回失败代码。

在 C 风格的伪代码中，我的行为将是：

do {
    result = function_with_side_effects(input_list[index++]);
} while (result == success && index < max_index);

所以，@sth 的答案再次执行我想要的确切行为，除了结果可能（应该？）被丢弃。 对于我的目的来说， dropWhileM_ 函数是等效的。 为什么 Control.Monad 中没有类似的函数或 takeWhileM_ ？ 我看到邮件列表上有类似的讨论，但似乎没有任何结果。

Answer 1

您可以定义序列 作为

sequence xs = foldr (liftM2 (:)) (return []) xs

liftM2 你一直看到的是你没有机会阻止m2，这可能是launchTheMissiles！

liftM2 :: (Monad m) => (a -> b -> c) -> m a -> m b -> m c
liftM2 f m1 m2 = do
    x1 <- m1
    x2 <- m2
    return (f x1 x2)

使用 guard如下所示似乎很有吸引力：

sequenceUntil p xs = foldr (myLiftM2 p (:)) (return []) xs
  where myLiftM2 p f m1 m2 = do
            x1 <- m1
            guard $ p x1
            x2 <- m2
            return (f x1 x2)

上面的代码将在您的应用程序中失败，因为 IO monad 不是 MonadPlus。

因此，握紧它的手一点

module Main where

import Control.Monad

printx :: Int -> IO Int
printx x = do
    print x
    return x

sequenceUntil :: (Monad m) => (a -> Bool) -> [m a] -> m [a]
sequenceUntil p xs = foldr (myLiftM2 (:) []) (return []) xs
  where myLiftM2 f z m1 m2 = do
            x1 <- m1
            if p x1 then do x2 <- m2
                            return $ f x1 x2
                    else return z

main :: IO ()
main = do
  let as :: [IO Int]
      as = map printx [1..10]
  ys <- sequenceUntil (< 4) as
  print ys

即使 as 是超过 1 到 10 的操作列表，输出是

1
2
3
4
[1,2,3]

丢弃结果然后微不足道：

sequenceUntil_ :: (Monad m) => (a -> Bool) -> [m a] -> m ()
sequenceUntil_ p xs = sequenceUntil p xs >> return ()

main :: IO ()
main = do
  let as :: [IO Int]
      as = map printx [1..]
  sequenceUntil_ (< 4) as

请注意 [1..]< 的使用/code> 显示新的组合器保持惰性。

---

您可能更喜欢 spanM：

spanM :: (Monad m) => (a -> Bool) -> [m a] -> m ([a], [m a])
spanM _ [] = return ([], [])
spanM p (a:as) = do
  x <- a
  if p x then do (xs,bs) <- spanM p as
                 return (x:xs, bs)
         else return ([x], as)

请注意，它与 span ，因为它在结果列表中包含失败的元素。 两人的第二个任务是剩下的行动。 例如：

*Main> (xs,bs) <- spanM (< 4) as
1
2
3
4
*Main> xs  
[1,2,3,4]
*Main> sequence bs
5
6
7
8
9
10
[5,6,7,8,9,10]

---

另一种选择：

untilM :: Monad m => (a -> Bool) -> [m a] -> m ()
untilM p (x:xs) = do
  y <- x
  unless (p y) $ untilM p xs

注意谓词的含义是补充的：

*Main> untilM (>= 4) as
1
2
3
4

Answer 2

我认为标准库中没有类似 takeWhileM 的东西，但您可以自己编写它，以便只执行所需的 IO：

takeWhileM :: (Monad m) => (a -> Bool) -> [m a] -> m [a]
takeWhileM _ [] = return []
takeWhileM p (a:as) =
   do v <- a
      if p v
         then do vs <- takeWhileM p as
                 return (v:vs)
         else return []

仅对提供的​​列表进行评估，直到有一个元素出现为止。发现，与谓词不匹配：

*Main> takeWhileM (<4) (map f [1..5])
1
2
3
4
[1,2,3]

Answer 3

编辑：现在我明白你在寻找什么了。

gbacon 发布了一个很好的 sequenceWhile 函数，这几乎是您需要的“原始”函数。

实际上，由于您只对副作用感兴趣，因此 sequenceWhile_ 应该足够了。 这是一个定义（再次受到 gbacon 的启发，投票给他！）：

sequenceWhile_ :: (Monad m) => (a -> Bool) -> [m a] -> m ()
sequenceWhile_ p xs = foldr (\mx my -> mx >>= \x -> when (p x) my)
                            (return ()) xs

您可以这样称呼：

Prelude Control.Monad> sequenceWhile (<4) $ map f [1..]

---

原始答案：

您不能只是从 IO 中“取消”值 Monad 与 takeWile 一起使用，但您可以“提升”takeWhile 以在 Monad 中使用！

liftM 函数将将函数 (a -> b) 转换为函数 (ma -> mb)，其中 m 是 Monad。

（顺便说一句，您可以通过在 Hoogle 上搜索其类型来找到这样的函数，在此案例通过搜索： Monad m => (a -> b) -> (ma -> mb)< /code>）

使用 liftM 你可以做到这一点：

Prelude> :m + Control.Monad
Prelude Control.Monad> let f x = print x >> return x
Prelude Control.Monad> liftM (takeWhile (<4)) $ mapM f [0..5]
0
1
2
3
4
5
[0,1,2,3]

现在，这可能不是你想要的。 在返回列表之前，mapM 会将 f 函数按顺序应用于整个列表。 然后将结果列表传递给提升的 takeWhile 函数。

如果您想在第三个元素之后停止打印，则必须停止调用 print。 这意味着，不要将 f 应用于此类元素。 因此，您最终会得到一些简单的结果，例如：

Prelude> mapM_ f (takeWhile (<4) [0..5])

---

顺便说一下，您是否想知道为什么 mapM 将在返回列表之前首先打印所有内容。 您可以通过用函数的定义替换函数来看到这一点：

mapM f [0..1]
=
sequence (map f [0..1])
=
sequence (f 0 : map f [1..1])
=
sequence (f 0 : f 1 : [])
=
sequence ((print 0 >> return 0) : f 1 : [])
= 
sequence ((print 0 >> return 0) : (print 1 >> return 1) : [])
=
do x  <- (print 0 >> return 0)
   xs <- (sequence ((print 1 >> return 1) : []))
   return (x:xs)
=
do x  <- (print 0 >> return 0)
   xs <- (do y  <- (print 1 >> return 1)
             ys <- sequence ([])
             return (y:ys))
   return (x:xs)
=
do x  <- (print 0 >> return 0)
   xs <- (do y  <- (print 1 >> return 1)
             ys <- return []
             return (y:ys))
   return (x:xs)
=
do x  <- (print 0 >> return 0)
   xs <- (do y <- (print 1 >> return 1)
             return (y:[]))
   return (x:xs)
=
do x  <- (print 0 >> return 0)
   xs <- (print 1 >> return (1:[]))
   return (x:xs)
=
do x <- (print 0 >> return 0)
   print 1
   return (x:1:[])
=
do print 0
   print 1
   return (0:1:[])

用函数的定义替换函数的过程称为等式推理。

如果我没有犯任何错误，您现在（希望）可以看到 mapM（使用 sequence）首先打印所有内容，然后然后返回一个列表。

Answer 4

您可以使用 "List" 包中的一个。

import Control.Monad.ListT (ListT)
import Data.List.Class (execute, fromList, joinM, takeWhile)
import Prelude hiding (takeWhile)

f x = print x >> return x
main =
  execute . takeWhile (< 4) .
  joinM $ fmap f (fromList [0..5] :: ListT IO Int)

• fromList [0..5] 创建一个包含 0..5 的单子列表，该列表不执行单子操作
• fmap f 到该列表会产生 ListT IO (IO Int) 仍然不执行单子操作，只包含单子​​操作。
• joinM 将其转换为 ListT IO Int。 当该项目被消耗时，每个包含的操作都会被执行，其结果将是列表中的值。
• takeWhile 泛化于任何List。 [] 和“Monad m => ListT m”都是List 的实例。
• execute 使用单子列表，执行其所有操作。
• 如果您对结果感兴趣，可以使用 "toList :: List m => ma -> ItemM m [a]" ("ItemM (ListT IO)”是IO）。 所以在本例中它是“toList :: ListT IO a -> IO [a]”。 更好的是，您可以继续使用高阶函数（例如 scanl 等）在执行时处理单子列表。

Answer 5

最近，您可以使用包含 方便的函数，如 takeWhileM、dropWhileM、deleteByM 等等。