有关 Sybase ASE 12.5 中各个密码过期间隔的报告

Question

我想运行一份报告以确保每个用户的密码设置为每 30 天过期，但过期间隔似乎没有存储在 syslogins 中？

Answer 1

您可以使用以下过程获取报告：

use sybsystemprocs
go
----------------------------------------------------------------------------
print 'sp__helpexpire'
----------------------------------------------------------------------------
if exists (select 1 from sysobjects where  type = "P" and  name = "sp__helpexpire")
        drop proc sp__helpexpire
go
create procedure sp__helpexpire
as
begin
  set nocount on
  declare @swexpire int
  select @swexpire=value from master.dbo.sysconfigures
    where name = 'systemwide password expiration'
  print "Serverwide password expire: %1!" ,@swexpire
  print ""
  print "Logins:"
  print "=============================================================="
  select l.name login , case a.int_value
      when null then @swexpire
      else a.int_value end "expire in days"
    from master.dbo.syslogins l , master.dbo.sysattributes a
    where l.suid *= a.object
      and a.object_type='PS'
      and a.attribute=0
      and object_cinfo='login'
  print ""
  print "Roles:"
  print "=============================================================="
  select r.name "role name", case a.int_value
      when null then @swexpire
      else a.int_value end "expire in days"
    from master.dbo.syssrvroles r , master.dbo.sysattributes a
    where r.srid *= a.object
      and a.object_type='PS'
      and a.attribute=0
      and object_cinfo='role'
end
go

检查那些系统过程（存储在 sybsystemprocs 数据库中）的源代码总是一个好主意，这些系统过程对您正在查找的记录进行操作（在本例中为 sp_addlogin、sp_modifylogin）

Answer 2

您可以使用 sp_configure 设置所有用户密码过期日期，

sp_configure "systemwide password expiration", 30
go

将设置所有用户密码在 30 天后过期。 但不确定是否可以在报告中读取该值。 默认值为 0。

Answer 3

尝试

exec sp_displaylogin

获取以该用户身份登录的单个用户的设置权限。