VBA：在用户窗体上使用 WithEvents

Question

我有一个 Word 用户窗体，其中包含 60 多个不同类型的控件。 我想在每次触发 control_change 事件时评估表单并更改表单提交按钮的启用状态。 但是，我真的不想编写和维护 60 个更改事件处理程序。

Answer 1

您可以创建一个事件接收器类，其中包含特定类型的所有控件的事件处理代码。

例如，创建一个名为 TextBoxEventHandler 的类，如下所示：

Private WithEvents m_oTextBox as MSForms.TextBox

Public Property Set TextBox(ByVal oTextBox as MSForms.TextBox)
    Set m_oTextBox = oTextBox
End Property

Private Sub m_oTextBox_Change()
    ' Do something
End Sub

现在您需要创建 & 为表单上适当类型的每个控件连接该类的一个实例：

Private m_oCollectionOfEventHandlers As Collection

Private Sub UserForm_Initialise()

    Set m_oCollectionOfEventHandlers = New Collection

    Dim oControl As Control
    For Each oControl In Me.Controls

        If TypeName(oControl) = "TextBox" Then

            Dim oEventHandler As TextBoxEventHandler
            Set oEventHandler = New TextBoxEventHandler

            Set oEventHandler.TextBox = oControl

            m_oCollectionOfEventHandlers.Add oEventHandler

        End If

    Next oControl

End Sub

请注意，您需要将事件处理程序实例添加到集合中的原因只是为了确保它们保持引用状态，从而不会被垃圾收集器在你完成它们之前。

显然，这种技术可以扩展到处理其他类型的控制。 您可以为每种类型使用单独的事件处理程序类，也可以为需要处理的每种控件类型使用具有成员变量（以及关联的属性和事件处理程序）的单个类。

Answer 2

在这种情况下，您几乎没有选择，因为事件处理程序无法在 VBA/VB6 中共享

选项 1： 使用从每个事件处理程序调用的中央处理函数。

Sub Control1_ChangeEvent()
  CommonChangeEvent // Just call the common handler, parameters as needed
End Sub

Sub Control2_ChangeEvent()
  CommonChangeEvent
End Sub
...
Sub CommonChangeEvent(/* Add necessary parameters */)
  //Do the heavy lifting here
End Sub

选项 2：在控件数组中组织控件。

Sub TextBox_ChangeEvent(Index As Integer)
  CommonChangeEvent
End Sub

Sub OtherControlType_ChangeEvent(Index As Integer)
  CommonChangeEvent
End Sub

将这两个选项结合起来，您的事件处理程序总数将大大减少，而其余的处理程序只是一个真正的事件处理程序的无脑存根。