如何公开和引发 vb.net winforms 用户控件的自定义事件

Question

请阅读此内容 帖子。 我遇到了与这篇文章中描述的相同的问题，但我尝试在 VB.net 而不是 c# 中执行。

我很确定要做到这一点我必须使用自定义事件。 （我使用代码转换网站来了解自定义事件。）因此，当我在 IDE 中键入以下内容时：

Public Custom Event AddRemoveAttendees As EventHandler

它会扩展为以下代码片段。

Public Custom Event AddRemoveAttendees As EventHandler
    AddHandler(ByVal value As EventHandler)

    End AddHandler

    RemoveHandler(ByVal value As EventHandler)

    End RemoveHandler

    RaiseEvent(ByVal sender As Object, ByVal e As System.EventArgs)

    End RaiseEvent
End Event

但我不知道该怎么办。 直到今天我还从未听说过自定义事件。

我想要的底线是让按钮的单击事件冒泡到用户控件的容器。 我知道我可以包装自己的事件，但在我沿着这条路走得更远之前，我至少想了解自定义事件。

赛斯

Answer 1

要使用自定义事件冒泡另一个控件的事件，您可以这样做：

Public Custom Event AddRemoveAttendees As EventHandler
    AddHandler(ByVal value As EventHandler)
        AddHandler _theButton.Click, value
    End AddHandler

    RemoveHandler(ByVal value As EventHandler)
        RemoveHandler _theButton.Click, value
    End RemoveHandler

    RaiseEvent(ByVal sender As Object, ByVal e As System.EventArgs)
        ' no need to do anything in here since you will actually '
        ' not raise this event; it only acts as a "placeholder" for the '
        ' buttons click event '
    End RaiseEvent
End Event

在 AddHandler 和 RemoveHandler 中，您只需将附加或删除给定事件处理程序的调用传播到/来自控件的 Click 事件。

为了扩展一下自定义事件的使用，这里是自定义事件的另一个示例实现：

Dim _handlers As New List(Of EventHandler)
Public Custom Event AddRemoveAttendees As EventHandler

    AddHandler(ByVal value As EventHandler)
        _handlers.Add(value)
    End AddHandler

    RemoveHandler(ByVal value As EventHandler)
        If _handlers.Contains(value) Then
            _handlers.Remove(value)
        End If
    End RemoveHandler

    RaiseEvent(ByVal sender As Object, ByVal e As System.EventArgs)
        For Each handler As EventHandler In _handlers
            Try
                handler.Invoke(sender, e)
            Catch ex As Exception
                Debug.WriteLine("Exception while invoking event handler: " & ex.ToString())
            End Try
        Next
    End RaiseEvent
End Event

现在，正如上面所示，它除了常规事件声明之外几乎没有其他作用：

Public Event AddRemoveAttendees As EventHandler

它提供了类似的机制，允许附加事件处理程序并删除，并引发该事件。 自定义事件添加的是额外的控制级别； 您可以围绕添加、删除和引发事件编写一些代码，在其中您可以强制执行规则，并稍微调整将要发生的情况。 例如，您可能希望限制附加到事件的事件处理程序的数量。 为了实现这一点，您可以更改上面示例中的 AddHandler 部分：

    AddHandler(ByVal value As EventHandler)
        If _handlers.Count < 8 Then
            _handlers.Add(value)
        End If
    End AddHandler

如果您不需要这种详细的控制，我认为不需要声明自定义事件。

Answer 2

如果您想要与您提到的其他帖子中相同的东西，这里有 VB.NET 等效项：

Public Custom Event AddRemoveAttendees As EventHandler

    AddHandler(ByVal value As EventHandler)
        AddHandler SaveButton.Click, value
    End AddHandler

    RemoveHandler(ByVal value As EventHandler)
        RemoveHandler SaveButton.Click, value
    End RemoveHandler

End Event

但我认为这不是一个好主意，因为事件的 sender 参数将是 < code>Button，而不是您的 UserControl...

相反，您可以订阅 Button.Click 事件并引发您自己的事件（没有显式访问器）