如何将 PDF 设置为 Crystal Report 的默认导出选项？

Question

我正在 Visual Studio 2008 的 WinForms 中使用 CrystalDecisions.CrystalReports.Engine.ReportDocument。现在，当用户单击导出按钮时，对话框默认将报表保存为 CrystalReports 格式的文件。 可以将选择器更改为 PDF，但我收到的具体请求（我已经搜索了太多时间试图找到）是将“导出报告”对话框默认为 PDF 格式选项。

有谁知道如何做到这一点？

Answer 1

从 CR XI 开始，我知道的唯一方法是将导出对话框替换为您自己的对话框。 您可以将自己的按钮添加到 CrystalReportViewer 控件并隐藏其导出按钮。

下面是用您自己的按钮/事件处理程序替换导出按钮的 vb.net 代码...

Public Shared Sub SetCustomExportHandler(ByVal crv As CrystalDecisions.Windows.Forms.CrystalReportViewer, ByVal export_click_handler As EventHandler)
        For Each ctrl As Control In crv.Controls
            'find the toolstrip
            If TypeOf ctrl Is ToolStrip Then
                Dim ts As ToolStrip = DirectCast(ctrl, ToolStrip)

                For Each tsi As ToolStripItem In ts.Items

                    'find the export button by it's image index
                    If TypeOf tsi Is ToolStripButton AndAlso tsi.ImageIndex = 8 Then

                        'CRV export button
                        Dim crXb As ToolStripButton = DirectCast(tsi, ToolStripButton)

                        'clone the looks of the export button
                        Dim tsb As New ToolStripButton
                        With tsb
                            .Size = crXb.Size
                            .Padding = crXb.Padding
                            .Margin = crXb.Margin
                            .TextImageRelation = crXb.TextImageRelation

                            .Text = crXb.Text
                            .ToolTipText = crXb.ToolTipText
                            .ImageScaling = crXb.ImageScaling
                            .ImageAlign = crXb.ImageAlign
                            .ImageIndex = crXb.ImageIndex
                        End With

                        'insert custom button in it's place
                        ts.Items.Insert(0, tsb)

                        AddHandler tsb.Click, export_click_handler

                        Exit For
                    End If
                Next

                Exit For
            End If
        Next

        'hide the default export button
        crv.ShowExportButton = False
    End Sub

然后在单击处理程序中您将显示自定义的 SaveFileDialog 并最终调用 ReportDocument.ExportToDisk 方法。 通过这种方式，您可以将对话框的标题和文件名设置为有用的内容，当然还可以设置默认导出类型。