当复选框被选中/取消选中时，如何触发 Flex 列表中的 itemEditEnd 事件？

Question

我有一个 List 组件，它具有嵌入式 CheckBox itemEditor，它也充当 itemRenderer。 它将每个项目显示为带有标签的简单 CheckBox。

但是，直到我单击列表之外的内容后，itemEditEnd 事件才会被触发。 我希望在选中或取消选中复选框后触发它。

我正在考虑在 CLICK 事件处理程序中手动调度 ListEvent.ITEM_EDIT_END ，但随后 itemEditEnd 事件将被调度两次。 一定有更好的方法来做到这一点。

有任何想法吗？

谢谢。

Answer 1

这是我想出的解决方案。 我更改了列表以使用该组件仅作为 itemRenderer，而不是作为 itemRenderer 和 itemEditor。 然后，我添加了一个 MouseEvent.CLICK 处理程序，以从 itemRenderer 调用列表中的函数来执行必要的操作：

我的列表组件：

package
{
    import mx.controls.List;
    import mx.core.ClassFactory;

    public class CustomCheckBoxList extends List
    {
        public function CustomCheckBoxList()
        {
            super();

            itemRenderer = new ClassFactory(CheckBoxRenderer);
        }

        public function dispatchSelectionEvent(item:Object, selected:Boolean):void
        {
            // Take action here...
        }
    }
}

我的 ItemRenderer：

package
{
    import flash.events.MouseEvent;

    import mx.controls.CheckBox;

    public class CheckBoxRenderer extends CheckBox
    {
        public function CheckBoxRenderer()
        {
            super();
        }

        override protected function clickHandler(event:MouseEvent):void
        {
            super.clickHandler(event);

            CustomCheckBoxList(listData.owner).dispatchSelectionEvent(data, selected);
        }
    }
}

Answer 2

我刚刚遇到这个。 我使用的是自定义组件而不是直接插入方法，这在使用渲染器作为编辑器时有效。

请注意，Flex 人员显然提出了这样的想法：用户希望在确定要提交的状态之前多次切换复选框……此时他们会按 Enter 键。 多么明显啊！

我的解决方案是合成一个相当于按 Enter 的键盘事件。 棘手的部分是必须使用 callLater() 方法来调度事件，因为在调用复选框的单击处理程序之前，列表控件不会在编辑器上注册其键盘侦听器。 这是我的自定义渲染器/编辑器组件中复选框的单击处理程序：

private function onClick(value:Object):void {
    newValue = value;
    var list:ListBase = ListBase(owner);
    list.callLater(dispatchEvent, [new KeyboardEvent(KeyboardEvent.KEY_DOWN, true, false, Keyboard.ENTER, Keyboard.ENTER)]); 
}