使用 MooseX::Declare 关闭内联构造函数

Question

您好，

作为我上一个关于驼鹿的问题的后续，我'现在我们遇到了一个新问题。 我有一个 Moose 类，它使用 方案 12 用于扩展非 Moose 父类。 就是这样：

package MyApp::CGI;

### TODO: make this work with MooseX::Declare?

use Moose;
extends 'CGI::Application';

sub new { 
    my $class = shift;
    my $obj = $class->SUPER::new( @_ );
    return $class->meta->new_object( __INSTANCE__ => $obj, @_ );
}

sub setup {
    my $self = shift;
    $self->start_mode( 'main' );

    my @methods = map { $_->name } $self->meta->get_all_methods;

    $self->run_modes( map  { /^rm_(.+)$/  => $_ }
                      grep { /^rm_/ }
                      @methods
                    );        
}

这很好用。 我还有一个此类的子类，它使用 MooseX::Declare。 但是，因为我现在重写默认的 Moose 构造函数，所以我的子类发出此警告：

Not inlining 'new' for MyApp::CGI::Login since it is not inheriting the default Moose::Object::new
If you are certain you don't need to inline your constructor, specify inline_constructor => 0 in your call to MyApp::CGI::Login->meta->make_immutable

由于 MooseX::Declare 在幕后自动调用 make_immutable，我无法弄清楚如何让它打开 inline_constructor => 0 参数。

Answer 1

感谢 IRC 上的一些人，我能够破解这个问题。 声明类 mutable 足以关闭 MooseX::Declare 中的 auto_make_immutable 标志，因此我可以手动执行此操作。 （当然，这也适用于非 MX::Declare 类。）

修订版本：

use MooseX::Declare;

class MyApp::CGI extends CGI::Application is mutable { 

    around new { 
        my $obj = $self->SUPER::new( @_ );
        return $self->meta->new_object( __INSTANCE__ => $obj, @_ );
    }

    method setup {
        $self->start_mode( 'main' );

        my @methods = map { $_->name } $self->meta->get_all_methods;

        $self->run_modes( map  { /^rm_(.+)$/  => $_ }
                          grep { /^rm_/ }
                          @methods
                        );
    }

    __PACKAGE__->meta->make_immutable( inline_constructor => 0 );
 }