如何获取经过的时间（以毫秒为单位）

Question

由于 VB6 中字符串连接的性能相当弱，因此我正在测试几个 StringBuilder 实现。 为了查看它们运行了多长时间，我目前使用内置

Timer

函数，它只提供午夜后经过的秒数。

有没有办法（我想通过导入系统函数）来获得毫秒精度的东西？

Answer 1

是的，您可以使用Win32 API：

DWORD WINAPI GetTickCount(void);

要在VB6中导入它，请这样声明：

Private Declare Function GetTickCount Lib "kernel32" () As Long

在操作之前和之后调用它，然后计算经过的时间差。

Answer 2

将以下代码放入 Stopwatch 类中：

Option Explicit

Private Declare Function QueryPerformanceCounter Lib "Kernel32" (X As Currency) As Boolean
Private Declare Function QueryPerformanceFrequency Lib "Kernel32" (X As Currency) As Boolean

Private m_startTime As Currency
Private m_freq As Currency
Private m_overhead As Currency

Public Sub start()
    QueryPerformanceCounter m_startTime
End Sub

Public Function ElapsedSeconds() As Double
    Dim currentTime As Currency
    QueryPerformanceCounter currentTime
    ElapsedSeconds = (currentTime - m_startTime - m_overhead) / m_freq
End Function

Public Function ElapsedMilliseconds() As Double
    ElapsedMilliseconds = ElapsedSeconds * 1000
End Function

Private Sub Class_Initialize()
    QueryPerformanceFrequency m_freq
    Dim ctr1 As Currency
    Dim ctr2 As Currency
    QueryPerformanceCounter ctr1
    QueryPerformanceCounter ctr2
    m_overhead = ctr2 - ctr1
End Sub

您可以按如下方式使用它：

Dim sw as StopWatch
Set sw = New StopWatch
sw.Start

' Code you want to time

Debug.Print "Code took " & sw.ElapsedMilliseconds " ms"

Answer 3

您也可以考虑使用不同的方法。 尝试从具有足够迭代次数的循环中调用例程，以获得可测量的时间差。

Answer 4

您可以使用两个 Win32 API：

• QueryPerformanceCounter：获取事件开始和结束时的计数。
• QueryPerformanceFrequency：获取每个时间点的刻度数第二。

它们使用 LARGE_INTEGER 来表示 64 位数字。

Answer 5

MSDN 知识库文章 Q172338 如何使用 QueryPerformanceCounter 来计时代码中提供了代码和说明

Answer 6

有一个托马斯·爱迪生的故事，他正在面试一些未来的工程师。

他要求他们确定灯泡的体积。 考生 A 测量它，然后使用球体体积的公式和颈部体积的另一个公式，依此类推。 考生 B 将其装满水并倒入量杯中。 你认为谁得到了这份工作？

运行 1000 次，然后查看前后的手表。 秒=毫秒。

Answer 7

我总是在某个模块中使用它（不过也可以在一个类中）。 此代码允许您维护最多六个计时器，并且具有高精度：

Option Explicit

Private Declare Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As Currency) As Long
Private Declare Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As Currency) As Long

Private cFrequency As Currency
Private cCounters(0 To 5) As Currency

Public Sub StartCounter(Optional lCounterIndex As Long)
    QueryPerformanceFrequency cFrequency
    QueryPerformanceCounter cCounters(lCounterIndex)
End Sub

Public Function GetCounter(Optional lCounterIndex As Long) As Double
    Dim cCount As Currency

    QueryPerformanceFrequency cFrequency
    QueryPerformanceCounter cCount
    GetCounter = Format$((cCount - cCounters(lCounterIndex) - CCur(0.0008)) / cFrequency, "0.000000000")
End Function

Public Function Scientific(ByVal dValue As Double) As String
    Dim lMultiplier As Long
    Dim vNames As Variant

    lMultiplier = 5
    vNames = Array("peta", "tera", "giga", "mega", "kilo", "", "milli", "micro", "nano", "pico", "femto")
    If Abs(dValue) < 1 Then
        While Abs(dValue) < 1
            dValue = dValue * 1000
            lMultiplier = lMultiplier + 1
        Wend
    ElseIf Abs(dValue) >= 1000 Then
        While Abs(dValue) >= 1000
            dValue = dValue / 1000
            lMultiplier = lMultiplier - 1
        Wend
    End If

    Scientific = Format$(dValue, "0.000") & " " & vNames(lMultiplier)
End Function

Answer 8

您可以尝试使用 System::Diagnostics::Stopwatch

Imports System.Diagnostics

Dim sw As New Stopwatch()
sw.Start()
// do something
LOG("Elapsed " + sw.ElapsedMilliseconds + " ms")