如何获取 Microsoft Word 中下拉菜单的值

Question

我有一个 Microsft Word 文档，其中有一个下拉菜单。 我正在尝试编写一个宏来获取下拉列表的值并执行计算。 如何获取下拉菜单的值？

Answer 1

首先，您可以通过您指定的名称（“属性”框中的“书签”字段）或您添加的字段序列中的编号来获取对下拉列表的引用。

然后使用 Result 属性显示当前选定的值。

我创建了一个空白文档，上面有两个下拉列表（显示“表单”工具栏，然后单击一个按钮以在光标位置插入该控件）：

ColorDropdown
  red
  green
  blue

SizeDropdown
  small
  medium
  large

然后我编写了一些测试例程：

Sub ListDropDowns()
  Dim doc As Document, f As FormField
  Set doc = ActiveDocument

  For Each f In doc.FormFields
    Say f.Name & " = " & f.Result
  Next
End Sub

Sub ShowChosenColor()
  Dim f As FormField
  Set f = ActiveDocument.FormFields("ColorDropdown")
  Say "color = " & f.Result
End Sub

Sub Say(s As String)
  Debug.Print s
End Sub

这些是来自“立即”的 ListDropDowns 和 ShowChosenColor 的结果窗口：

ColorDropdown = blue
SizeDropdown = large

color = blue

更多立即窗口测试：

set doc = ActiveDocument

? doc.FormFields(1).Name
ColorDropdown

? doc.FormFields(2).Name
SizeDropdown

? doc.FormFields(2).Result
large


sName = doc.FormFields(2).Name
? sName
SizeDropdown

sSize = doc.FormFields(sName).Result
? sSize
large