如何在 Perl 中循环访问类的所有方法？

Question

如何在 Perl 中循环访问一个类的所有方法？ 有没有关于 Perl 内省或反射的好的在线参考？

Answer 1

Todd Gardner 使用 Moose 的建议很好，但他选择的示例代码并不是很有帮助。

如果您正在检查非 Moose 使用类，则需要执行以下操作：

use Some::Class;
use Class::MOP;

my $meta = Class::MOP::Class->initialize('Some::Class');

for my $meth ( $meta->get_all_methods ) {
    print $meth->fully_qualified_name, "\n";
}

请参阅 Class::MOP::Class 文档 了解有关如何进行内省的更多详细信息。

您还会注意到我使用了 Class::MOP 而不是 Moose。 Class::MOP（MOP = 元对象协议）是 Moose 构建的基础。 如果您正在使用非 Moose 类，那么使用 Moose 进行内省不会给您带来任何好处。

如果您愿意，可以使用 Moose () 和 Moose::Meta::Class->initialize 代替 CMOP。

Answer 2

您可以使用已经提供的答案轻松获取类的已定义方法的列表。 然而，Perl 是一种动态语言，这意味着以后可能会定义更多方法。 实际上没有办法获取任何特定类将处理的所有方法的列表。 有关此类内容的更多详细信息，我在 掌握 Perl 中提供了几章。

人们在不告诉您限制的情况下给您（并投票）答案。

Adam 提到了他的 Class::Inspector，但它并没有真正起作用，因为它试图做一些动态语言不会做的事情（而且是静态的:)例如，这里有一个片段，其中 Class::Inspector 不返回任何方法，但我仍然可以调用 VERSION 方法（以及isa 和 can）：

    BEGIN {

package Foo;

our $VERSION = '1.23'
}

use Class::Inspector;

my $methods = Class::Inspector->methods( 'Foo' );

print "Methods are [@$methods]\n"; # reports nothing

print Foo->VERSION, "\n";

这是另一种情况，我可以调用任何我喜欢的方法，但 Class::Inspector 只返回 AUTOLOAD （并且仍然缺少VERSION、isa 和 can）：

BEGIN {

package Foo;

our $VERSION = '1.23';

my $object = bless {}, __PACKAGE__;

sub AUTOLOAD { $object }

}

use Class::Inspector;

my $methods = Class::Inspector->methods( 'Foo' );

print "Methods are [@$methods]\n"; # reports only "AUTOLOAD"

print Foo->dog->cat->bird, "\n";

奇怪的是，每个人似乎都忽略了 UNIVERSAL，可能是因为他们没有明确处理它，因为它只是虚拟的在@ISA。 我可以向每个类添加一个 debug 方法，而 Class::Inspector 仍然会错过它，即使它是一个已定义的方法：

BEGIN {

sub UNIVERSAL::debug { "Hello debugger!\n" }    
package Foo;
}

use Class::Inspector;

my $methods = Class::Inspector->methods( 'Foo' );

print "Methods are [@$methods]\n"; # still reports nothing

print Foo->debug, "\n";

Class::MOP 具有相同的限制。

并非每个模块都会使用 AUTOLOAD，但这也不是一个晦涩或罕见的功能。 如果您不介意错过某些方法，那么 Class::Inspector 或 Class::MOP 可能还可以。 它只是不会为您提供在每种情况下可以对类或对象调用的每个方法的列表。

如果您有一个类或一个对象，并且您想知道是否可以调用特定方法，请使用 can()。 将其包装在 eval 块中，以便可以对甚至不是对象的事物调用 can() ，在这些情况下仍然返回 false，而不是死亡：

if( eval { $object->can( 'method_name' ) } )
    {
    $object->( @args );
    }

Answer 3

在一般情况下，您必须检查符号表（除非您使用 Moose）。 例如，要列出 IO::File 包中定义的方法：

use IO::File;
no strict 'refs';
print join ', ', grep { defined &{"IO::File::$_"} } keys %{IO::File::};

哈希 %{IO::File::} 是 的符号表IO::File package，grep 过滤掉非子例程条目（例如包变量）。

要扩展它以包含继承的方法，您必须递归搜索父类的符号表 (@IO::File::ISA)。

下面是一个完整的示例：

sub list_methods_for_class {
    my $class = shift;
    eval "require $class";
    no strict 'refs';
    my @methods = grep { defined &{$class . "::$_"} } keys %{$class . "::"};
    push @methods, list_methods_for_class($_) foreach @{$class . "::ISA"};
    return @methods;
}

有关包和符号表的更多信息，请参阅 perlmod 手册页。

Answer 4

取决于您是否指的是任何课程，或者您是否正在实现自己的课程。 对于后者，我使用 Moose，它为这些功能提供了非常干净的语法。 来自食谱：

my %attributes = %{ $self->meta->get_attribute_map };
for my $name ( sort keys %attributes ) {
   my $attribute = $attributes{$name};

   if (   $attribute->does('MyApp::Meta::Attribute::Trait::Labeled')
   # ... keeps on

Answer 5

您可能需要 Class::Inspector->methods('Your::Class')。

纳夫说道。

Answer 6

我会把它留在这里，以备我忘记时使用。 这是极其强大的； 可惜的是，它太偏僻了，大多数 Perl 程序员从未体验过它。

package Foo;
use strict;
sub foo1 {};
sub foo2 {};
our $foo3 = sub{};
my $foo4 = "hello, world!";

package Bar;
use strict;

# woo, we're javascript!
(sub {
    *Bar::foo1 = sub { print "hi!"; };
    *Bar::foo2 = sub { print "hello!"; };
    $Bar::foo1 = 200;
})->();

package main;
use strict;
use Data::Dumper;      
$Data::Dumper::Deparse = 1;

print Dumper \%Data::Dumper::;
print Dumper \%Foo::;
print Dumper \%Bar::;