如何处理临时文件？

Question

在我的应用程序中，我的用户可以将文件（pdf/xls/doc）导入到表中或将它们导出到文件夹中。 现在我想直接打开这些文件。

到目前为止我能够： - 获得一个独特的名字 - 将 blob 文件保存到生成的文件中 - 打开它

问题是我不知道如何删除（或更新）该文件，之后该文件将被用户关闭。

如果有人可以帮助我，我会非常高兴:)

这是我的代码的快照：

procedure OpenTemporaryFile(AFileExtension: String; AKey: Integer;
            AMyConnection: TMyConnection);
     Var
       qrDocuments : TMyQuery ;
       TmpName,ExtName: string;
       TempFileName: TFileStream;
    begin
       //Generate an unique tmp file located into user temp folder
       TmpName:=  FileGetTempName('~SI');
       ExtName:= ChangeFileExt(TmpName, AFileExtension);
       //Change files extension so that Shellexecute will be able to open the file
       RenameFile(TmpName,ExtName );
       //Creating the FileStream (data is fetched from an blob field)
       TempFileName := TFileStream.Create(ExtName, fmOpenReadWrite );

       qrDocuments := TMyQuery.create(nil);
       try
        qrDocuments.Connection := AMyConnection;
        qrDocuments.Close;
        qrDocuments.SQL.Clear;
        qrDocuments.SQL.Text:='Select Id,FileName,Data from files where Id = :prId And Data IS NOT NULL';
        qrDocuments.ParamByName('prId').AsInteger := AKey;
        qrDocuments.open;
        TBlobField(qrDocuments.FieldByName('Data')).SaveToStream(TempFileName);
       finally
          TempFileName.Free;
          qrDocuments.free;
       end;
       ShellExecute(Application.Handle, 'open', Pchar(ExtName), '', '', SW_SHOWNORMAL);
       DeleteFile( ExtName);
    end;

Answer 1

不幸的是，现在有 4 个赞成票 Remy Lebeau 的这个答案，当该技术根本不适用于大多数应用程序时。 也许其中一位支持者可以发布一段代码片段，允许在文件仍然使用 FILE_FLAG_DELETE_ON_CLOSE 标志打开的情况下使用 Acrobat Reader 打开 PDF 文件？

无论如何，您可以结合此处的一些技巧以获得最佳结果：

• 拥有应用程序使用的临时文件的内部列表。
• 程序关闭时，浏览临时文件列表并尝试删除它们。 如果其中一些失败（因为它们仍然在外部应用程序中打开），请使用 gabr 给您的代码。
• 每当您需要新的临时文件时，请首先浏览内部文件列表并尝试重用其中一个。 仅当失败时才创建一个新文件（并将其名称添加到列表中）。

我更喜欢这种方法来注册所有文件以在重新启动时删除，因为我不确定您的应用程序可能会打开多少个临时文件 - 也许可以使用 MOVEFILE_DELAY_UNTIL_REBOOT< 注册的文件数量有限制/代码>？ 这是一个系统范围的资源，我只会很少使用。

Answer 2

一种可能性是将每个临时文件添加到系统启动期间删除的文件列表中。

在 Windows NT 平台上（自 Windows 2000 起），您只需调用 MoveFileEx 函数，第二个参数（目标）设置为 nil，并带有标志 MOVEFILE_DELAY_UNTIL_REBOOT。

在 Windows 9x 上，这要复杂得多。 您必须编辑文件 %WINDIR%\wininit.ini 并将条目写入 [Rename] 部分。

MSDN 条目如何移动当前正在使用的文件描述了这两种技术。

函数 DSiMoveOnReboot（免费 DSiWin32 库的一部分）可以处理这两种操作系统。 如果您传递一个空字符串作为第二个参数，它将在重新启动时删除源文件。

function DSiMoveOnReboot(const srcName, destName: string): boolean;
var
  wfile: string;
  winit: text;
  wline: string;
  cont : TStringList;
  i    : integer;
  found: boolean;
  dest : PChar;
begin
  if destName = '' then
    dest := nil
  else
    dest := PChar(destName);
  if DSiIsWinNT then
    Result := MoveFileEx(PChar(srcName), dest, MOVEFILE_DELAY_UNTIL_REBOOT)
  else
    Result := false;
  if not Result then begin
    // not NT, write a Rename entry to WININIT.INI
    wfile := DSiGetWindowsFolder+'\wininit.ini';
    if FileOpenSafe(wfile,winit,500,120{one minute}) then begin
      try
        cont := TStringList.Create;
        try
          Reset(winit);
          while not Eof(winit) do begin
            Readln(winit,wline);
            cont.Add(wline);
          end; //while
          if destName = '' then
            wline := 'NUL='+srcName
          else
            wline := destName+'='+srcName;
          found := false;
          for i := 0 to cont.Count - 1 do begin
            if UpperCase(cont[i]) = '[RENAME]' then begin
              cont.Insert(i+1,wline);
              found := true;
              break;
            end;
          end; //for
          if not found then begin
            cont.Add('[Rename]');
            cont.Add(wline);
          end;
          Rewrite(winit);
          for i := 0 to cont.Count - 1 do
            Writeln(winit,cont[i]);
          Result := true;
        finally cont.Free; end;
      finally Close(winit); end;
    end;
  end;
end; { DSiMoveOnReboot }

Answer 3

使用 Win32 API CreateFile() 函数打开文件，指定 FILE_FLAG_DELETE_ON_CLOSE 标志，然后将生成的句柄传递给 THandleStream 对象，以便您仍然可以使用 SaveToStream()。

另外，您的代码中存在一个错误 - 您向 ShellExecute() 传递了错误类型的句柄。 它需要一个窗口句柄，但您正在传递一个文件句柄，更糟糕的是，您在释放 TFileStream 之后访问文件句柄，从而关闭该句柄。

Answer 4

也许您可以将它们存储在您熟悉的某个文件夹中（例如 TEMP 文件夹中带有您的应用程序名称的子文件夹），并在用户下次加载您的应用程序时清除该文件夹的内容？ 或者您可以安装额外的清除实用程序并将其设置为在自动启动中运行。

关于重新启动后清除文件的另一个想法 - 您可以在启动时清除子文件夹中的所有内容，或者列出您创建的文件的上次修改时间、上次大小，将此列表存储在 XML 文件中，然后删除或更新比较您的临时子文件夹的内容以及该列表中的文件详细信息？

Answer 5

如果我没记错的话，CreateFile 有一个标志告诉 Windows 一旦文件的最后一个句柄被关闭，它应该删除该文件。 因此，正常创建文件，关闭并使用共享拒绝无和上面提到的标志重新打开它。 然后让外部应用程序打开它并自行关闭它。 一旦外部应用程序关闭该文件，这将导致 Windows 删除该文件。

（我没有尝试过这个。）

Answer 6

在类 Unix 操作系统中，通常的技巧是打开它并立即删除。 它不会出现在目录中，但数据仍然分配给保持其打开的进程。 一旦它关闭（无论是进程死亡），文件系统都会回收空间。

这不是黑客攻击，它已被​​记录和支持（将打开的文件句柄算作文件的“引用”的结果，就像目录条目一样）。

也许Windows上有一些类似的技巧？ 我似乎记得 NTFS 支持对同一文件的多个引用（不，不是快捷方式）。 如果是这样，删除该文件但仍然保留最后一个引用作为临时资源可能会起作用。

显然，我只是在这里猜测......

Answer 7

实际上，我们的应用程序在特定的临时文件夹中创建文件。 当应用程序关闭时，文件将被删除。 如果应用程序未正确关闭，则下次执行（关闭时）所有文件都将被删除。

此外，您可以启动后台进程来删除不再打开的文件。 ShellExecute 返回一个句柄（在内部将此句柄与文件名关联）。 该后台进程必须测试不存在的进程的句柄并删除关联的文件。

请原谅英语不好。 ;-）

问候。