svn：如何自动在分支之间传输提交

Question

我想自动化这个过程：

1. 一个数字来自外部系统，比方说 35。
2. 搜索并找到在分支 A 的注释中有 #35 的 svn 提交。
3. 列出这些提交对之前提交的所有更改。
4. 将此更改应用于分支 B。

例如，如果版本 95 的注释中有 #35 并在版本 94 上引入了新文件，请添加此 [添加文件 x.txt]。 rev 132 的注释中有#35，它更改了 x.txt 中的一行。 还添加此[更改第 n 行，文件 x.txt]。 等等。 现在我们有一个更改列表：

[Add File x.txt]
[Change line n, file x.txt]
...

将此更改应用到分支 B。

这可以在 svn 上实现吗？ 命令是什么（或命令行以外的方式）？ 是否存在涵盖这些操作所需命令的文档？

Answer 1

您需要知道刚刚提交的修订版本，然后签出/切换到分支 B，如果修订版本是 123 和 125，则使用 svn merge -c 123,125。

另请参阅 SvnBook 合并

Answer 2

如果您的开发人员有足够的纪律，总是在提交日志消息中写入票号，您可以使用此 Perl 脚本来搜索日志消息中包含指定单词的修订。 首先检出分支 B 的工作副本，然后在工作副本内运行，

perl merge-ticket.pl searchWord sourceURL

指定分支 A 的票号和存储库 URL。该脚本将分支 A 中的匹配修订合并到工作副本中。

# merge-ticket.pl
use strict;
use XML::Parser;

if ($#ARGV != 1) {
    die "usage: $0 searchWord sourceURL\n";
    exit 1;
}
my $searchWord = $ARGV[0];
my $sourceUrl = $ARGV[1];

my @revisions = ();

my $revision;
my $inMsg;
my $message;

sub startTag {
    my($parser, $tag, %attrs) = @_;

    if ($tag eq 'logentry') {
        $revision = $attrs{'revision'};
    } elsif ($tag eq 'msg') {
        $inMsg = 1;
        $message = '';
    }
}

sub endTag {
    my($parser, $tag) = @_;

    if ($tag eq 'msg') {
        $inMsg = 0;
        if ($message =~ /\b$searchWord\b/) {
            push(@revisions, $revision);
            print "$revision: $message\n";
        }
    }
}

sub characterData {
    my($parser, $data) = @_;

    if ($inMsg) {
        $message .= $data;
    }
}

# Search commit log messages for word.
my $command = "svn log --xml $sourceUrl";
open(INPUT, "$command|") || die "Error executing $command: $!\n";
my $parser = new XML::Parser(
        Handlers => {
            Start => \&startTag,
            End => \&endTag,
            Char => \&characterData});
$parser->parse(*INPUT);
close(INPUT);

if ($#revisions < 0) {
    print "No log messages containing $searchWord found\n";
    exit 1;
}

# Merge found revisions into working copy.
my $changes = join(',', reverse(@revisions));
$command = "svn merge -c$changes $sourceUrl";
print "$command\n";
system $command;