如何使用 VBA 使用记录集填充组合框

Question

专家交流中提供了一些文献以及 teck Republic< /a> 关于使用combobox.recordset 属性填充Access 表单中的组合框。

这些控件通常在控件的“rowsource”属性中填充“SELECT *”字符串，引用应用程序客户端上可用的表或查询。 当我需要在组合框中显示服务器端数据时，我创建一个临时本地表并导入请求的记录。 这非常耗时，特别是对于大表。

能够使用记录集填充组合框控件将允许用户直接显示来自服务器端的数据。

受前面 2 个示例的启发，我编写了一些代码，如下所示：

Dim rsPersonne as ADODB.recordset
Set rsPersonne = New ADODB.Recordset

Set rsPersonne.ActiveConnection = connexionActive
rsPersonne.CursorType = adOpenDynamic
rsPersonne.LockType = adLockPessimistic
rsPersonne.CursorLocation = adUseClient

rsPersonne.Open "SELECT id_Personne, nomPersonne FROM Tbl_Personne"

fc().Controls("id_Personne").Recordset = rsPersonne

其中：

• connexionActive：是我与数据库服务器的永久 ADO 连接
• fc()：是我当前/活动的表单
• 控件（“id_Personne”）：是 用于填充的组合框控件 公司员工名单
• 2003年Access版本

不幸的是，它不起作用！

在调试模式下，我能够检查记录集是否已正确创建，包含请求的列和数据，并且是否正确关联到组合框控件。 不幸的是，当我显示表单时，我不断收到一个空的组合框，其中没有任何记录！ 非常感谢任何帮助。

编辑：

这个记录集属性确实可用于特定的组合框对象，而不是标准控件对象，几天前我很惊讶地发现它。 我已经尝试过使用组合框的回调函数，或者使用组合框的“addItem”方法填充列表。 所有这些都非常耗时。

Answer 1

要设置接受记录集行源的控件，请执行以下操作：

Set recordset = currentDb.OpenRecordset("SELECT * FROM TABLE", dbOpenSnapshot)
Set control.recordset = recordset

当然可以与 DAO 记录集一起使用，我还没有尝试过 ADO 记录集，因为我没有任何真正的理由使用它们。

当这样做时，简单的重新查询将无法刷新数据，您必须重复设置语句。

Answer 2

如前所述，您必须将 RowSourceType 设置为“Table/Query”（或“Table/Requête”，如果是法语），以便在组合框中显示查询结果。

您的内存问题是由于打开记录集（rsPersonne）而不关闭它而引起的。 您应该在关闭/卸载表单时关闭它们（但您又会遇到范围问题，因为记录集是在函数中声明的，而不是在表单中声明的​​）。

您还可以尝试使用 Access 的内置查询创建器创建并保存查询，并将相同的查询插入组合框的 RowSource 中。 这样查询就可以在 Access 中得到验证和编译。

Answer 3

使用 Recordset 属性的好方法，感谢您的提示！

Patrick，您在页面上显示的方法有一个很大的缺点（我自己也尝试过）：值列表只能是 32 KB，如果超过此限制，函数将抛出错误。
回调方法有一个很大的缺点，它非常慢，并且每个条目都会调用一次，这使得它无法用于较长的列表。
使用记录集方法效果很好。 我需要这个，因为我的 SQL 字符串超过 32 KB（WHERE ID IN(x,x,x,x,x...) 的大量索引值）。

下面是一个简单的函数，它使用这个想法将记录集设置到组合框：（

' Fills a combobox with the result of a recordset.
'
' Works with any length of recordset results (up to 10000 in ADP)
' Useful if strSQL is longer than 32767 characters
'
' Author: Christian Coppes
' Date: 16.09.2009
'
Public Sub fnADOComboboxSetRS(cmb As ComboBox, strSQL As String)
    Dim rs As ADODB.Recordset
    Dim lngCount As Long

   On Error GoTo fnADOComboboxSetRS_Error

    Set rs = fnADOSelectCommon(strSQL, adLockReadOnly, adOpenForwardOnly)

    If Not rs Is Nothing Then
        If Not (rs.EOF And rs.BOF) Then
            Set cmb.Recordset = rs
            ' enforces the combobox to load completely
            lngCount = cmb.ListCount
        End If
    End If

fnADOComboboxSetRS_Exit:
    If Not rs Is Nothing Then
        If rs.State = adStateOpen Then rs.Close
        Set rs = Nothing
    End If
    Exit Sub

fnADOComboboxSetRS_Error:
    Select Case Err
        Case Else
            fnErr "modODBC->fnADOComboboxSetRS", True
            Resume fnADOComboboxSetRS_Exit
    End Select
End Sub

函数 fnADOSelectCommon 打开一个 ADO 记录集并将其返回。函数 fnErr 显示一个包含错误的消息框（如果有的话）。）

当该函数关闭时打开的记录集内存应该没有问题。 我测试了它，没有看到任何内存增加，这些内存在使用组合框关闭表单后没有释放。

在表单的卸载事件中，您还可以使用“Set rs=Me.Comboboxname.Recordset”，然后将其关闭。 对于内存来说，这不是必需的，但释放打开的连接可能更好（如果与后端数据库服务器一起使用）。

干杯，

克里斯蒂安

Answer 4

我发现了窍门...组合框控件的“rowSourceType”属性必须设置为“表/查询”。 显示现在可以了，但我现在有另一个内存问题。 由于我在表单上使用这些 ADO 记录集，因此每次浏览表单时 Access 的内存使用量都会增加。 停止浏览或关闭表单都不会释放内存，从而导致 MS Access 不稳定并经常冻结。 如果我无法解决这个问题，我会提出一个问题

Answer 5

组合框控件没有记录集属性。 它确实有一个 RowSource 属性，但 Access 需要其中有一个 SQL 字符串。

您可以将 RowSourceType 更改为用户定义的“回调”函数的名称。 通过将自己定位在 RowSourceType 上并按 F1，访问帮助将为您提供更多信息，包括示例代码。 当我想向用户提供可用报告、驱动器盘符或无法通过 SQL 查询获得的其他数据的列表时，我会使用此类函数。

我不明白你的第三段关于直接使用来自服务器端的数据的意思。 或者更确切地说，我不明白使用标准查询的问题是什么。

Answer 6

在 MS Access 中，没问题，但在 VB 中，您可以使用 adodc (Jet 4.0) 使用类似的内容：

Private sub Form1_Load()
   with Adodc1
     .commandtype = adcmdtext
     .recordsource = "Select * from courses"
     .refresh

     while not .recordset.eof
           combo1.additem = .recordset.coursecode
           .recordset.movenext
     wend
   end with
End Sub