如何在 VB.net 中指定 volatility 的等效项？

Question

我正在尝试编写用于消息传递的调用队列的无锁版本。 这并不是为了任何严肃的事情，只是为了了解线程。

我相对确定我的代码是正确的，除非指令被重新排序或在寄存器中完成。 我知道我可以使用内存屏障来停止重新排序，但如何确保值立即写入内存？

Public Class CallQueue
    Private first As New Node(Nothing) 'owned by consumer'
    Private last As Node = first 'owned by producers'
    Private Class Node
        Public ReadOnly action As Action
        Public [next] As Node
        Public Sub New(ByVal action As Action)
            Me.action = action
        End Sub
    End Class

    Private _running As Integer
    Private Function TryAcquireConsumer() As Boolean
        Threading.Thread.MemoryBarrier()

        'Dont bother acquiring if there are no items to consume'
        'This unsafe check is alright because enqueuers call this method, so we never end up with a non-empty idle queue'
        If first.next Is Nothing Then Return False

        Threading.Thread.MemoryBarrier()

        'Try to acquire'
        Return Threading.Interlocked.Exchange(_running, 1) = 0
    End Function
    Private Function TryReleaseConsumer() As Boolean
        Do
            Threading.Thread.MemoryBarrier()

            'Dont release while there are still things to consume'
            If first.next IsNot Nothing Then Return False

            Threading.Thread.MemoryBarrier()

            'Release'
            _running = 0

            Threading.Thread.MemoryBarrier()

            'It is possible that a new item was queued between the first.next check and releasing'
            'Therefore it is necessary to check if we can re-acquire in order to guarantee we dont leave a non-empty queue idle'
            If Not TryAcquireConsumer() Then Return True
        Loop
    End Function

    Public Sub QueueAction(ByVal action As Action)
        'Enqueue'
        'Essentially, this works because each node is returned by InterLocked.Exchange *exactly once*'
        'Each node has its .next property set exactly once, and also each node is targeted by .next exactly once, so they end up forming a valid tail'
        Dim n = New Node(action)
        Threading.Interlocked.Exchange(last, n).next = n

        'Start the consumer thread if it is not already running'
        If TryAcquireConsumer() Then
            Call New Threading.Thread(Sub() Consume()).Start()
        End If
    End Sub
    Private Sub Consume()
        'Run until queue is empty'
        Do Until TryReleaseConsumer()
            first = first.next
            Call first.action()
        Loop
    End Sub
End Class

Answer 1

VB.NET 中没有与 C# 的 volatile 关键字等效的东西。 相反，通常建议使用 MemoryBarrier 。 还可以编写辅助方法：

Function VolatileRead(Of T)(ByRef Address As T) As T
    VolatileRead = Address
    Threading.Thread.MemoryBarrier()
End Function

Sub VolatileWrite(Of T)(ByRef Address As T, ByVal Value As T)
    Threading.Thread.MemoryBarrier()
    Address = Value
End Sub

还有一个有用的博客 post关于这个话题。

Answer 2

使用 BCL 中的 Thread.VolatileRead() 和 VolatileWrite() 方法。

http://msdn.microsoft.com/en-us /library/system.threading.thread.volatileread.aspx

Answer 3

从 .NET 4.5 开始，他们向 BCL 添加了两个新方法来模拟 volatile 关键字：Volatile.Read 和 Volatile.Write 。 它们应该完全等同于读取/写入易失性字段。 您可以在 VB.NET 中清楚地使用它们。 它们更好（其中更好 == 更快）比Thread.VolatileRead/Thread.VolatileWrite 因为他们使用半栅栏而不是全栅栏。

Answer 4

我不是这个主题的专家，所以如果我错了，希望其他人能纠正我。 据我了解，内存优化问题目前只是一个理论上的问题，不一定会在现实中发生。 但话虽如此，我认为通过使用 Interlocked API 进行内存访问（无论 MemoryBarrier 如何），您不会受到影响。

不幸的是，VB.NET 中没有 volatility 的等效项。 它没有用普通属性修饰，而是一个特殊的编译器生成的修饰符。 您需要使用反射来发出具有此类字段的类型。

当我对 .NET 框架中的线程有疑问时，我经常参考以下资源。 它很长，但希望您会发现它很有用。

http://www.yoda.arachsys.com/csharp/threads/printable。 shtml

Answer 5

Mono.Cecil 阅读器代码使 FieldType As
requiredModifierType，ModifierType 为 System.Runtime.CompilerServices.IsVolatile。

Answer 6

您还可以使用 Thread.VolatileRead() 和 Thread.VolatileWrite() 为“Volatile”编写一个属性，并使所有属性/变量都具有该属性，例如：

<Volatile()>
Protected Property SecondsRemaining as Integer

将此写在某处，但现在似乎无法找到它...