使用 SqlConnection 和 VB.NET 创建 ASP.NET 聚合源

Question

这似乎是 Scott Mitchell 撰写的一篇关于在 ASP.NET 3.5 中创建联合提要的精彩文章。 对我来说，问题是它使用 C# 和 Linq，目前我对这两种语言不太熟悉。

http://dotnetslackers。 com/articles/aspnet/How-to-create-a-synmination-feed-for-your-website.aspx

有谁知道哪里可能存在 System.ServiceModel.Syndicate 的示例> 可以使用 VB.NET 和 SQLConnection 对象生成像本文这样的联合提要的命名空间？

我环顾四周，发现每个示例似乎都是用 C# 和 Linq 生成的（这可能证明我需要尽快学习它们，而不是稍后学习它们）。

Answer 1

您现在可能已经明白了，但这里有一个为了完整性和一些 VB 热爱而实现的实现（以及 Necromancer 徽章 :)

aspx 页面很简单，请注意 60 秒缓存：

<%@ Page Language="vb" AutoEventWireup="false" CodeBehind="Default.aspx.vb" Inherits="YourProject._Default" %>
<%@ OutputCache Duration="60" VaryByParam="Type" %>

您可能需要考虑使用 HttpHandler，但这也可以正常工作。

背后的代码：

Imports System.ServiceModel.Syndication
Imports System.Xml

Partial Public Class _Default
  Inherits System.Web.UI.Page

  Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    Dim dbConn As String = "[your db connection]"
    Dim format As FeedFormats = GetFeedFormat()
    Dim posts As New List(Of SyndicationItem)

    Using cnn As New SqlClient.SqlConnection(dbConn)
      cnn.Open()

      Using cmd As New SqlClient.SqlCommand("SELECT ID, Title, Text, Url, Created FROM Posts", cnn)
        Dim reader As SqlClient.SqlDataReader = cmd.ExecuteReader

        While reader.Read
          Dim item As New SyndicationItem(reader.Item("Title"), reader("Text"), New Uri(reader("Url")))

          posts.Add(item)
        End While
      End Using
    End Using

    Dim feed As New SyndicationFeed("Your feed title", "Your feed description", New Uri("http://yourdomain.com"), posts)

    Using feedWriter As XmlWriter = XmlWriter.Create(Response.OutputStream)
      Select Case format
        Case FeedFormats.Atom
          Response.ContentType = "application/rss+xml"

          Dim atomFormatter As New Atom10FeedFormatter(feed)
          atomFormatter.WriteTo(feedWriter)
        Case FeedFormats.Rss
          Response.ContentType = "application/atom+xml"

          Dim rssFormatter As New Rss20FeedFormatter(feed)
          rssFormatter.WriteTo(feedWriter)
      End Select
    End Using
  End Sub

  Private Function GetFeedFormat() As FeedFormats
    If Request.QueryString("format") = "atom" Then
      Return FeedFormats.Atom
    Else
      Return FeedFormats.Rss
    End If
  End Function

  Public Enum FeedFormats
    Rss = 1
    Atom = 2
  End Enum
End Class

最后，为了超级完整，创建表的 SQL 脚本：

CREATE TABLE [dbo].[Posts](
 [ID] [int] IDENTITY(1,1) NOT NULL,
 [Title] [nvarchar](50) NOT NULL,
 [Text] [ntext] NOT NULL,
 [Url] [nvarchar](50) NOT NULL,
 [Created] [datetime2](7) NOT NULL,
 CONSTRAINT [PK_Posts] PRIMARY KEY CLUSTERED 
(
 [ID] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]

GO

ALTER TABLE [dbo].[Posts] ADD  CONSTRAINT [DF_Posts_Url]  DEFAULT ('') FOR [Url]
GO

ALTER TABLE [dbo].[Posts] ADD  CONSTRAINT [DF_Posts_Created]  DEFAULT (getdate()) FOR [Created]
GO

完成。 VB.NET、SQL 连接、System.ServiceModel.Synmination 命名空间，并且没有 LINQ。 :)

更新：于 2010 年 11 月 11 日获得死灵法师徽章。 耶！ 谢谢！ :)

Answer 2

我不知道在 VB.Net 中使用这些对象的示例，但有多种方法可以将 C# 代码转换为 VB.Net。 您可以使用像 SharpDevelop 这样的 IDE，也可以使用多种免费在线转换器中的任何一种。

我最喜欢的技术是下载或剪切并粘贴源代码到 Visual Studio 中，然后用 C# 编译项目。 然后使用Reflector将IL反汇编为VB.Net。 通过这样做，您可以将 C# 与 VB.Net 进行比较，如果您愿意的话，它可以帮助您了解相似之处并更快地学习 C#。