在 Clojure 循环中重新定义 let'd 变量

Question

好的。 我一直在修改 Clojure，并且不断遇到同样的问题。 让我们看一下这段代码：

(let [x 128]
  (while (> x 1)
    (do
      (println x)
      (def x (/ x 2)))))

现在我希望它打印出一个以 128 开头的序列：相反

128
64
32
16
8
4
2

，它是一个无限循环，一遍又一遍地打印 128。 显然我预期的副作用没有发挥作用。

那么我该如何在这样的循环中重新定义 x 的值呢？ 我意识到这可能不像 Lisp（也许我可以使用一个在其自身上递归的匿名函数），但如果我不知道如何设置这样的变量，我会发疯的。

我的另一个猜测是使用 set!，但这会给出“无效的分配目标”，因为我没有处于绑定形式。

请告诉我这是如何工作的。

Answer 1

如果您认为在纯函数中拥有可变局部变量将是一个很好的方便功能，而且不会造成任何损害，因为该函数仍然保持纯函数，您可能会对这个邮件列表讨论感兴趣，其中 Rich Hickey 解释了他从语言中删除它们的原因。 为什么不使用可变局部变量？

相关部分：

如果局部变量是变量，即可变的，那么闭包可以关闭
可变状态，并且考虑到闭包可以逃逸（不需要一些额外的
禁止相同），结果将是线程不安全的。 还有人
肯定会这样做，例如基于闭包的伪对象。 结果
这将是 Clojure 方法中的一个巨大漏洞。

如果没有可变的局部变量，人们就被迫使用 recur，一种函数式的
循环构造。 虽然乍一看这可能看起来很奇怪，但它就像
简洁如带有突变的循环，结果模式可以是
在 Clojure 的其他地方重用，即 recur、reduce、alter、commut 等
都（逻辑上）非常相似。 尽管我可以检测到并且
防止变异闭包逃逸，我决定保持这种方式
为了一致性。 即使在最小的上下文中，非变异循环也是如此
比变异更容易理解和调试。 无论如何，瓦尔斯
可以在适当的时候使用。

后续帖子的大部分内容都涉及实现 with-local-vars 宏；）

Answer 2

def 定义了一个顶级变量，即使您在函数或某些代码的内部循环中使用它。 你在 let 中得到的不是变量。 根据 let 的文档：

用let创建的局部变量不是变量。 一旦创建，他们的价值观就永远不会改变！

（强调不是我的。）这里的示例不需要可变状态； 您可以使用loop和recur。

(loop [x 128]
  (when (> x 1)
    (println x)
    (recur (/ x 2))))

如果你想变得更奇特，你可以完全避免显式的循环。

(let [xs (take-while #(> % 1) (iterate #(/ % 2) 128))]
  (doseq [x xs] (println x)))

如果您确实想要使用可变状态，atom 可能会起作用。

(let [x (atom 128)]
  (while (> @x 1)
    (println @x)
    (swap! x #(/ %1 2))))

（您不需要 do；while 会为您将其主体包装在一个显式的主体中。）如果您真的非常想要这样做对于 vars 你必须做这样可怕的事情。

(with-local-vars [x 128]
  (while (> (var-get x) 1)
    (println (var-get x))
    (var-set x (/ (var-get x) 2))))

但这非常丑陋，而且根本不是 Clojure 惯用的。 为了有效地使用 Clojure，您应该尝试停止考虑可变状态。 尝试以非函数式风格编写 Clojure 代码肯定会让您发疯。 一段时间后，您可能会惊喜地发现实际上很少需要可变变量。

Answer 3

变量（这就是当你“定义”某些东西时得到的）并不意味着被重新分配（但可以）：

user=> (def k 1)
#'user/k
user=> k
1

没有什么可以阻止你这样做：

user=> (def k 2)
#'user/k
user=> k
2

如果你想要一个线程本地可设置的“位置”，你可以使用“绑定”和“设置！”：

user=> (def j) ; this var is still unbound (no value)
#'user/j
user=> j
java.lang.IllegalStateException: Var user/j is unbound. (NO_SOURCE_FILE:0)
user=> (binding [j 0] j)
0

那么你可以写一个像这样的循环：

user=> (binding [j 0]
         (while (< j 10)
           (println j)
           (set! j (inc j))))
0
1
2
3
4
5
6
7
8
9
nil

但我认为这是非常不惯用的。

Answer 4

您可以更惯用地使用 iterate 和 take-while 来代替，

user> (->> 128
           (iterate #(/ % 2))
           (take-while (partial < 1)))

(128 64 32 16 8 4 2)
user>