VB6.0中的记录集

Question

我正在使用 VB6 从记录集中的数据库检索数据...因此，在使用 SQL 中的 Select 检索数据时，我添加了一个名为 Comments 的列，以便在记录集中，表的所有列+“注释”列都会出现...我不想（而且我不能）更新数据库中的任何内容，因为我只是现在从数据库“获取”数据...

现在，当我传递获取的数据进行验证时，如果记录集中的特定行是错误的，我想用相应的错误填充“注释”列）...当我这样做我收到一条错误消息“我无权这样做！！（更新‘评论’栏”……

现在我的问题是“我可以通过什么方式解决这个问题？？？”..我尝试复制此记录集，现在填充了“注释”列（在复制的记录集中），这又显示了相同的错误...看来这可能是因为重复的记录集（记录集）只保留了记录集的属性原来的...

你能帮忙解决这个问题吗？？？ 有什么方法可以复制记录集（不继承其属性）？？？？？？

Answer 1

我认为您只是问如何执行断开连接的记录集。
为此，您只需更改记录集的光标位置即可。

Dim rstTest as ADODB.RecordSet
Set rstTest = New ADODB.RecordSet
With rstTest
   .CursorLocation = adUseClient
   .Open "your sql here", your_connection_object, adOpenStatic, adLockBatchOptimistic, adCmdText
   ' now disconnect it and force the local copy
   .ActiveConnection = Nothing
End With

Answer 2

不完全是您正在寻找的，但这就是我这样做的方法：

1. 创建一个类来封装记录集（“客户”表的“客户”类）
2. 将您的 Comment 属性添加到该类而不是记录集中
3. 将 Validate 方法添加到你的班。 将其写入您的 Comment 属性（我使用 Errors 集合）
4. 读取记录集
5. 将其解析为“新客户”
6. 验证
7. 检查 Comment 属性（或 Errors 集合）

Answer 3

您可以使用 MSDataShape 及其 SHAPE..APPEND 语法将新字段附加到 ADO 记录集。 下面是一个使用 Jet（又名 MS Access）的简单示例：

Sub ShapeAppendField()

  On Error Resume Next
  Kill Environ$("temp") & "\DropMe.mdb"
  On Error GoTo 0

  Dim cat
  Set cat = CreateObject("ADOX.Catalog")
  With cat
    .Create _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & _
        Environ$("temp") & "\DropMe.mdb"

    Dim jeng
    Set jeng = CreateObject("JRO.JetEngine")
    jeng.RefreshCache .ActiveConnection

    Set .ActiveConnection = Nothing
  End With

  Dim con
  Set con = CreateObject("ADODB.Connection")
  With con
    .ConnectionString = _
        "Provider=MSDataShape;" & _
        "Data Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & _
        Environ$("temp") & "\DropMe.mdb"
    .CursorLocation = 3
    .Open

    .Execute _
    "CREATE TABLE Test (" & _
    "existing_col INTEGER NOT NULL);"
    .Execute _
    "INSERT INTO Test (existing_col)" & _
    " VALUES (1);"

    Dim rs
    Set rs = CreateObject("ADODB.Recordset")
    With rs
      .CursorType = 2
      .LockType = 4
      .Source = _
          "SHAPE {" & _
          " SELECT existing_col" & _
          " FROM Test" & _
          "} APPEND NEW adInteger AS new_col"

      Set .ActiveConnection = con
      .Open
      Set .ActiveConnection = Nothing

      .Fields("new_col").value = 55
      MsgBox .GetString
      .Close

    End With
  End With
End Sub