使用 Erlang Regex 删除空格

Question

我想删除所有空白，即制表符/空格/换行符。

T = {xmlelement,"presence",
                                         [{"xml:lang","en"}],
                                         [{xmlcdata,<<"\n">>},
                                          {xmlelement,"priority",[],
                                              [{xmlcdata,<<"5">>}]},
                                          {xmlcdata,<<"\n">>},
                                          {xmlelement,"c",
                                              [{"xmlns",
                                                "http://jabber.org/protocol/caps"},
                                               {"node","http://psi-im.org/caps"},
                                               {"ver","0.12.1"},
                                               {"ext","cs ep-notify html"}],
                                              []},
                                          {xmlcdata,<<"\n">>}]}.

我尝试了以下方法，但它不起作用：

trim_whitespace(Input) ->
re:replace(Input, "(\r\n)*", "").

Answer 1

如果要删除字符串中的所有内容，则需要将全局选项传递给 re:replace()。 您也只是使用该正则表达式替换换行符。 该调用可能应该如下所示：

trim_whitespace(Input) -> re:replace(Input, "\\s+", "", [global]).

Answer 2

我遇到了同样的问题......来这里分享我更高效的工作：

trim(Subject) ->
  {match, [[Trimmed]|_]} = re:run(Subject, "^\\s*([^\\s]*(?:.*[^\\s]+)?)\\s*$", 
    [{capture, all_but_first, binary}, global, dollar_endonly, unicode, dotall]),
  Trimmed.

想法非常相似。 正则表达式更好。

Answer 3

您问题中的所有空白都在 cdata 部分中 - 为什么不直接从元组中过滤掉这些空白呢？

remove_cdata(List) when is_list(List) ->
    remove_list_cdata(List);
remove_cdata({xmlelement, Name, Attrs, Els}) ->
    {xmlelement, Name, remove_cdata(Attrs), remove_cdata(Els)}.

remove_list_cdata([]) ->
    [];
remove_list_cdata([{xmlcdata,_}|Rest]) ->
    remove_list_cdata(Rest);
remove_list_cdata([E = {xmlelement,_,_,_}|Rest]) ->
    [remove_cdata(E) | remove_list_cdata(Rest)];
remove_list_cdata([Item | Rest]) ->
    [Item | remove_list_cdata(Rest)].


remove_cdata(T) =:= 
    {xmlelement,"presence",
     [{"xml:lang","en"}],
     [{xmlelement,"priority",[],[]},
      {xmlelement,"c",
       [{"xmlns","http://jabber.org/protocol/caps"},
        {"node","http://psi-im.org/caps"},
        {"ver","0.12.1"},
        {"ext","cs ep-notify html"}],
       []}]}

Answer 4

re:replace 很棘手，需要记住：

Eshell V5.9.3.1  (abort with ^G)
1> re:replace("0 1  2    3 4 5 6 7 8 9", " ", "", [global, {return, list}]).
"0123456789"
2> re:replace("0 1  2    3 4 5 6 7 8 9", " ", "", [{return, list}]).
"01  2    3 4 5 6 7 8 9"
3> re:replace("0 1  2    3 4 5 6 7 8 9", " ", "").
[<<"0">>,[]|<<"1  2    3 4 5 6 7 8 9">>]