功能：构造一个整数列表 1..n

Question

这不是家庭作业。 我正在自学标准机器学习。 我也了解一点Scheme，所以这个问题应该可以用任何一种语言来回答。

我给自己布置的任务是编写一个函数，构造一个从 1 到 n 的整数列表。 例如，list(7) 应返回 [1,2,3,4,5,6,7]。 O(n) 的解决方案将是理想的。

在线性时间内反向构造一个列表（即 [n,n-1,..,1]）很容易：

fun list 1 = 1::nil
|   list n = n::list(n-1);

我尝试构造一个向前的列表是 O(n^2)，因为追加操作是线性的。

fun list 1 = 1::nil
|   list n = list(n-1) @ n::nil;

我的下一个尝试是从 nil 开始，将 n 附加到前面，然后向后递归到 1，从尾到前（从右到左）构建一个列表。但它根本不起作用。

fun list n = (if n = 1
              then 1
              else list(n-1) :: n) :: nil;

有些事情让我觉得我需要一个辅助函数来构建要在递归中使用的未终止列表，但我被难住了。

Answer 1

使用 基础库，

fun list n = List.tabulate (n, fn x => x + 1)

通过一个简单的累加器，

val list =
    let fun list' k 0 = k
          | list' k n = list' (n::k) (n-1)
    in list' nil end

这会从尾部开始构建一个列表。 如果您考虑减少，

   list 5
=> list' nil 5
=> list' (5::nil) 4
=> list' (4::5::nil) 3
=> list' (3::4::5::nil) 2
=> list' (2::3::4::5::nil) 1
=> list' (1::2::3::4::5::nil) 0
=> [1, 2, 3, 4, 5]

或者，

有些事情让我觉得我需要一个辅助函数来构建要在递归中使用的未终止列表，但我被难住了。

未终止列表的表示是一个接受列表并返回列表的函数：例如，要表示 10::_，您可以使用 fn x =>; 10::x。

fun list n =
    let fun list' m k = if m > n then k nil else
                        list' (m+1) (fn x => k (m::x))
    in list' 1 (fn x => x) end

再次，如果您考虑减少，

   list 5
=> list' 1 (fn x => x)
=> list' 2 (fn x => (fn x => x) (1::x))
=> list' 3 (fn x => (fn x => (fn x => x) (1::x)) (2::x))
=> list' 4 (fn x => (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::x))
=> list' 5 (fn x => (fn x => (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::x)) (4::x))
=> list' 6 (fn x => (fn x => (fn x => (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::x)) (4::x)) (5::x))
=> (fn x => (fn x => (fn x => (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::x)) (4::x)) (5::x)) nil
=> (fn x => (fn x => (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::x)) (4::x)) (5::nil)
=> (fn x => (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::x)) (4::5::nil)
=> (fn x => (fn x => (fn x => x) (1::x)) (2::x)) (3::4::5::nil)
=> (fn x => (fn x => x) (1::x)) (2::3::4::5::nil)
=> (fn x => x) (1::2::3::4::5::nil)
=> [1, 2, 3, 4, 5]

在这种情况下，可以对算法进行结构化，使普通数据结构足以满足累加器的要求，但使用延续作为累加器是一种非常强大且有用的技术，不应被忽视。

Answer 2

一种经典的方法是以相反的顺序构建它，然后反转它。 这是 O(n) 的两倍，当然也是 O(n)。

Answer 3

这是一个解决方案：

fun list n =
  let
    fun f 1 m = m::nil
    |   f n m = m::f (n-1) (m+1)
  in
    f n 1
  end;

Answer 4

这是使用辅助函数和支持尾递归的累加器的版本：

fun list n =
  let
    fun aux i acc = 
      if i > 0
      then aux (i-1) (i::acc)
      else acc
  in
    aux n nil
  end;

Answer 5

对于此类列表问题，解决更普遍的问题通常更容易。

如何构建一个包含整数i的列表，使得n <= i <= m按顺序排列？

该解决方案具有基本情况和归纳步骤：

• If n > m，列表为空。

• 如果n <= m，解决方案是写n，然后是问题的解决方案n+1 <= i <= m。

这种观点可以快速生成清晰、简洁的 ML 代码（经过测试）：

fun range n m = if n > m then [] else n :: range (n+1) m
fun list n = range 1 n

Answer 6

(define (iota n)
  (let f ((i n)(a '())
    (if (zero? i)
        (reverse a)
        (f (- i 1) (cons i a)))))