“0.0” 访问 TClientDataSet 的 TDateField 的 OldValue 时不是有效的时间戳

Question

当我在 TClientDataSet 中新插入的记录中使用以下代码时：

cdsMyDateField.OldValue <> Null

我得到一个 EConvertError：

''0.0' is not a valid timestamp'.

查看 Delphi 的 VCL 代码，它尝试将值转换为 TDateTime，这会导致此异常，因为值（Null）是无效的 DateTime，但当我比较变体时，我认为它会返回一个变体，在这种情况下该变体将为 Null，但这并没有发生，而是我得到了这个异常。

我知道我可以在比较值之前检查 DataSet.State = dsInsert ，就好像 State = dsInsert 每个 OldValue 都是 Null 一样，但我想了解为什么 OldValue 尝试转换值而不是全部返回 Null State = dsInsert 时的字段。

谁能给我一些启发吗？

Answer 1

在 Delphi 2009 update 2 和 Delphi 2007 中重现它，如下所示：

uses DB, DBClient;
procedure TTestForm1.TestButtonClick(Sender: TObject);
const
  SMyDateField = 'MyDateField';
  SMyIntegerField = 'MyIntegerField';
var
  MyClientDataSet: TClientDataSet;
  MyClientDataSetMyDateField: TField;
  MyClientDataSetMyIntegerField: TField;
  OldValue: Variant;
begin
  MyClientDataSet := TClientDataSet.Create(Self);
  MyClientDataSet.FieldDefs.Add(SMyDateField, ftDate);
  MyClientDataSet.FieldDefs.Add(SMyIntegerField, ftInteger);
  MyClientDataSet.CreateDataSet();
  MyClientDataSetMyDateField := MyClientDataSet.FieldByName(SMyDateField);
  MyClientDataSetMyIntegerField := MyClientDataSet.FieldByName(SMyIntegerField);
  MyClientDataSet.Insert();
  OldValue := MyClientDataSetMyIntegerField.OldValue;
  OldValue := MyClientDataSetMyDateField.OldValue;
end;

您总是收到此错误：

exception class EConvertError with message ''0.0' is not a valid timestamp'.

我不确定这是否被视为错误：

• 插入时技术上没有 OldValue，因此获取它可以引发异常
• MyClientDataSetMyIntegerField.OldValue 返回 0，但 MyClientDataSetMyDateField.OldValue 引发异常

更多说明：

• TCustomClientDataSet.GetFieldData 将获取实际的底层数据
• TDataSet.DataConvert 将底层数据转换为原生数据格式，执行有效性检查在需要的地方

编辑：根据 Fabricio 的评论，我强调 OldValue 在插入后在技术上是无效的。 所以从技术上来说这可能不是一个错误。

他的“新证据”可以通过检查 VCL/RTL 源来验证：

对于字段类型 ftDate、ftTime、ftDateTime，TDataSet.DataConvert 调用其本地 NativeToDateTime 函数，该函数填充 TimeStamp，然后使用 SysUtils.TimeStampToDateTime 转换该函数，而 SysUtils.TimeStampToDateTime 又调用 SysUtils。 ValidateTimeStamp，当时间部分小于零或日期部分小于或等于零时引发异常。

仅对于字段类型 ftDate 和 ftDateTime（TDateField 和 TDateTimeField），日期部分可以变为零，因此只有那些字段类型可以引发异常。
对于所有其他数据类型，NativeToDateTime 不会有问题：这些类型都允许结果填充零字节。

我刚刚检查了 RTL/VCL 历史记录：自从 Delphi 6 SysUtils.TimeStampToDateTime 调用 SysUtils.ValidateTimeStamp 以来，这种行为自 2001 年以来一直是相同的。

这使得很难将其视为错误。

Answer 2

我将 delphi 2007 与 MySQL 一起使用，我的解决方案是：

在 MySQL 查询中，我使用了：

select CAST(dateField AS CHAR) from table_name

... 使用 CAST 将字段转换为字符串值，我可以测试该值是否为 0000-00-00 ...然后使用字段的实际值。

Answer 3

FWIW，我遇到了同样的问题，这让我很头疼。 我的观点：行为不一致，因此即使仅从这个原因我也将其归类为错误。 这也是一个错误，因为在读取属性时引发异常是荒谬的，并且不符合属性的意图（最小惊喜原则）。我希望 OldValue 未分配，而不是在读取时引发异常。 （此外，某些问题已经存在很长时间的事实并不意味着它是否是一个错误。）

（编辑：用更多信息更新我的答案，包括我们的解决方法。也将同样的内容发布到质量控制报告中: http://qc.embarcadero.com/wc/qcmain.aspx?d =73852 )

我们在大量使用 datasnap/clientdatasets 的应用程序中也遇到了同样的问题。 然而，实际的问题不在于客户端数据集，而在于 SysUtils 中的时间戳验证例程，该例程显然错误地将值为 0.0 的时间戳验证为无效。

因此，解决方法/修复是针对 SysUtils 和验证例程，而不是针对 Tclientdataset。具体来说，在验证例程“ValidateTimeStamp()”中，时间部分被正确地比较<<。 0 但日期部分被错误地比较 <= 0。

因此，（合法的）0.0 日期时间值有时会转换为日期部分 = 0 的时间戳，并且当该值再次进行反向验证时（例如，当从数据集字段（如此处和 QC 报告中所示），会（错误地）引发异常。 因此，将时间戳的日期部分的验证更改为使用严格小于的简单修复可以解决 TClientDataset 暴露的问题。

这是我们基于 Delphi 7.1 的解决方法

(* SysUtils.pas line 10934 (Delphi 7.1)  *)
(**)(* fix - Timestamp values 0.0 erroneously designated as invalid *)
(* D7.1 *)
(* Walter Prins, originally patched May 2005, submitted 4 June 2009 *)
procedure ValidateTimeStamp(const TimeStamp: TTimeStamp);
begin
  if (TimeStamp.Time < 0) or (TimeStamp.Date < 0) then (* Changed TimeStamp.Date <= 0 to TimeStamp.Date < 0 *)
    ConvertErrorFmt(@SInvalidTimeStamp, [TimeStamp.Date, TimeStamp.Time]);
end;

Answer 4

Delphi 中的 TDateTime 是双精度型，其中日期存储在整数部分，时间存储在小数部分。 因此，在某种程度上，将空日期值转换为 0.0 是正确的。 由于您正在访问的基础字段是 TDateField （或 TDateTime 字段），因此它可能在内部进行转换。

此外，在 Delphi 中检查 Variant 是否为 Null 不再是正确的方法。 Null 变体仍会被分配，但值为 Null，而未分配的变体则没有值。 （想想 SQL 数据库 NULL 值）。 请改用 Variants.pas 单元中的 VarIsNull(const V: Variant) 函数； 如果变量为 null，则返回 true；如果有任何其他值，则返回 false。

Answer 5

我在激活“调试 DCU”选项的情况下调试了下面的代码
奇怪的是 SysUtils.ValidateTimeStamp 评估
日期 = 0 的时间戳无效，因此抛出
EConvertError 异常（而不是返回 Null 或未分配）。

所以最终结果是对 null 字段执行 OldValue 请求
dsInsert 状态是其无效。 该变体从不返回
因此，如果您使用 (field.OldValue <> Null) 或
VarIsNull(field.OldValue)。 之前抛出了异常。

cds_something 有两个字段（在设计时创建）：

• dt_Something
• num_something

代码：

var
  b: TClientDataset;
begin
  b := cds_somethin;
  b.Close;
  b.CreateDataSet;
  b.Insert;
  if b.FieldByName('DT_Sometinhg').OldValue <> Null then
    ShowMessage('Something wrong!!!')
  else
    ShowMessage('Normal');

  b.Cancel;

注意：我搞乱了这篇文章的原始编辑。 现在这是
对我所发现的内容的正确解释。

添加：使用其他一些字段类型（字符串、BCD、Float 和 Memo）和 OldValue 进行测试
未分配 - 因此上面的测试将评估为 false。

似乎只有 TDateField 和 TDateTimeField 显示该行为。 TTimeField 和 TSQLTimeStamp 评估正常 - 但 TSQLTimeStampField.OldValue 都不等于
为 Null 或未分配（wtf!!）...

代码片段稍作更改：

var
  b: TClientDataset;
begin
  b := cds_somethin;
  b.Close;
  b.CreateDataSet;
  b.Insert;
  /*
  if (b.FieldByName('DT_Something').OldValue <> Null) 
     and (b.FieldByName('DT_Something').OldValue <> Unassigned)  then
    ShowMessage('Something wrong!!!')
  else
    ShowMessage('Normal');
  */
  if (b.FieldByName('ts_Something').OldValue <> Null) 
     and (b.FieldByName('ts_Something').OldValue <> Unassigned)  then
    ShowMessage('Something wrong!!!')
  else
    ShowMessage('Normal');


  b.Cancel;

其中 ts_Something 是 TSQLTimeStampField。 这些字段是在设计时创建的。

Answer 6

这是 Midas/TClientDataSet 上与记录缓冲区相关的错误。 当您多次执行 AppendData 时，InternalCalc 字段显示为“not null”（记录缓冲区中错误的 null 标志）。 在Delphi 2010中，我们可以研究Midas.dll源代码（.cpp文件）。

http://img514.imageshack.us/img514/2840/wrongnull.jpg

我正在研究如何实施解决方案。

艾尔·冈萨雷斯.