查找文本组件（Flex/Actionscript）中鼠标悬停的单词

Question

是否有可能（如果可以的话如何）找出当光标/鼠标移动到 << 时，光标/鼠标位于哪个单词上？ mx：文本> 成分？ 因此，例如，当用户沿着句子（在文本组件内）移动鼠标时，每个单词都会随着移动而突出显示（我知道您可以在按下鼠标按钮时突出显示 - 但这不是我希望的方式）。

感谢您提供任何信息。

Answer 1

一种方法是：您需要创建自己的组件来扩展 mx:Text 组件。 我在这个例子中使用了MyText。 下面是 MyText 的完整代码：

<?xml version="1.0" encoding="utf-8"?>
<mx:Text xmlns:mx="http://www.adobe.com/2006/mxml" mouseMove="onMouseMove(event)" initialize="init()">
    <mx:Script>
        <![CDATA[

            // Text formats
            private var normalTextFormat:TextFormat;
            private var highlightTextFormat:TextFormat;

            // Saved word start and end indexes
            private var wordStartIndex:int = -1;
            private var wordEndIndex:int = -1;

            private function init():void
            {
                normalTextFormat = textField.getTextFormat();
                normalTextFormat.color = 0;
                highlightTextFormat = textField.getTextFormat();
                highlightTextFormat.color = 0xFF0000;
            }

            private function onMouseMove(event:MouseEvent):void
            {
                // Clear previous word highlight
                textField.setTextFormat(normalTextFormat, wordStartIndex, wordEndIndex);

                var charIndexUnderMouse:int = textField.getCharIndexAtPoint(event.localX, event.localY);
                wordStartIndex = charIndexUnderMouse;
                wordEndIndex = charIndexUnderMouse;

                // Find start of word
                while (text.charAt(wordStartIndex) != " " && wordStartIndex > 0)
                {
                    wordStartIndex--;
                }

                // Find end of word
                while (text.charAt(wordEndIndex) != " " && wordEndIndex < text.length)
                {
                    wordEndIndex++;
                }

                // Highlight character
                textField.setTextFormat(highlightTextFormat, wordStartIndex, wordEndIndex);
            }
        ]]>
    </mx:Script>

</mx:Text>

它的工作原理是访问 Text 组件内的 TextField 对象的方法，查找鼠标坐标下的字符索引，然后查找该字符所属的单词。 这是一个简单的示例，您可能需要使其更加复杂以供实际使用。

Answer 2

您需要使用 TextSnapshot 类。 您可以从文本控件的 textSnapshot 属性中获取它。 TextSnapshot 有一个 hitTestTextNearPos() 函数，您可以使用它来确定用户的鼠标靠近哪个字符。

...
var startIndex:Number;
...

private function textMouseMoveHandler(event:MouseEvent):void
{
    var snapshot:TextSnapshot = text.textSnapshot;
    var index = snapshot.hitTestTextNearPos(event.x, event.y);

    snapshot.setSelected(startIndex, index, true);
}

// I do not know how you want to begin the selection, so I put it here in the MouseEnter event.
private function textMouseEnterHandler(event:MouseEvent):void
{

    var snapshot:TextSnapshot = text.textSnapshot;
    startIndex = snapshot.hitTestTextNearPos(event.x, event.y);
}

不确定你想如何处理开始选择，但类似的东西应该可以工作。