无法在 Zsh 的 TAB 补全中对 Man 进行两个单词搜索

Question

问题：有一个制表符补全，它需要两个单词并计算它们与 Man 的最佳匹配，然后返回最佳匹配

示例：以下伪代码应给出我至少知道 Zsh 的反向菜单完成命令。 现在，如果没有 zgrep，我无法在手册中搜索手册。

man zsh:reverse <TAB>

其中“：”是我想要的分隔符。

初始问题：使用Zsh搜索手册时，按TAB键输入一个单词时，TAB补全会运行哪些文件？

Answer 1

我将尝试深入了解 zsh 补全系统的工作原理以及解决此问题的不完整方法。

当您在 zsh 中对 man 使用 TAB 补全时运行的文件位于 /usr/share/zsh/${ZSH_VERSION}/functions 目录下。 该树因发行版而异，但文件名为 _man，并提供 man、apropos 和 whatis 的补全。

调用 _man 后，其工作原理如下（粗略描述）：

1. 如果将 man 的完成和 --local-file 指定为第一个标志，则调用标准文件完成（< code>_files)
2. 从一组默认值/$MANPATH 构造 manpath 变量。 这是搜索手册页的地方，
3. 确定我们是否使用节号参数调用 man，如果是，则仅搜索
4. zstyle ':completion:*:manuals' 单独的 那些节使用了 -sections true，输出中的单独部分（不要在它们之间混合）
5. 调用 _man_pages 来提供匹配
6. _man_pages 的手册页列表使用 compfiles -ppages '' '' "$matcher" '' dummy '*' 做了一些魔法。 pages 是包含所请求部分的联机帮助页的所有目录的变量。 实际的通配模式是由隐式参数 $PREFIX 和 compfiles 的最后一个参数 - 在本例中 * 构造的。 这导致 /usr/share/man/man1 被转换为 /usr/share/man/man1/foo*
7. 新的 glob 模式列表被通配，获得所有与模式
8. _man_pages 匹配的文件，然后从文件中删除所有后缀，并使用 compadd 将它们添加到完成小部件选择列表中。

现在，如您所见，该列表手册页的数量直接由 $PREFIX 变量确定。 为了使 zsh:foo 仅列出包含单词 foo 的 zsh* 手册页，需要将其拆分为 >: 字符（如果有）。

_man_pages 中的以下添加部分解决了该问题（zsh 4.3.4）：

原始：

_man_pages() {
  local matcher pages dummy sopt

  zparseopts -E M+:=matcher

  if (( $#matcher )); then
    matcher=( ${matcher:#-M} )
    matcher="$matcher"
  else
    matcher=
  fi

  pages=( ${(M)dirs:#*$sect/} )

  compfiles -p pages '' '' "$matcher" '' dummy '*'
  pages=( ${^~pages}(N:t) )

  (($#mrd)) && pages[$#pages+1]=($(awk $awk $mrd))

  # Remove any compression suffix, then remove the minimum possible string
  # beginning with .<->: that handles problem cases like files called
  # `POSIX.1.5'.

  [[ $OSTYPE = solaris* ]] && sopt='-s '
  if ((CURRENT > 2)) ||
      ! zstyle -t ":completion:${curcontext}:manuals.$sect" insert-sections
  then
    compadd "$@" - ${pages%.(?|<->*(|.gz|.bz2|.Z))}
  else
    compadd "$@" -P "$sopt$sect " - ${pages%.(?|<->*(|.gz|.bz2|.Z))}
  fi
}

已修改（查找 ##mod 注释）：

_man_pages() {
  local matcher pages dummy sopt

  zparseopts -E M+:=matcher

  if (( $#matcher )); then
    matcher=( ${matcher:#-M} )
    matcher="$matcher"
  else
    matcher=
  fi

  pages=( ${(M)dirs:#*$sect/} )

  ##mod
  # split components by the ":" character
  local pref_words manpage_grep orig_prefix
  # save original prefix (just in case)
  orig_prefix=${PREFIX}
  # split $PREFIX by ':' and make it an array
  pref_words=${PREFIX//:/ }
  set -A pref_words ${=pref_words}
  # if there are both manpage name and grep string, use both
  if (( $#pref_words == 2 )); then
      manpage_grep=$pref_words[2]
      # PREFIX is used internally by compfiles
      PREFIX=$pref_words[1]
  elif (( $#pref_words == 1 )) && [[ ${PREFIX[1,1]} == ":" ]]; then
      # otherwise, prefix is empty and only grep string exists
      PREFIX=
      manpage_grep=$pref_words[1]
  fi


  compfiles -p pages '' '' "$matcher" '' dummy '*'
  ##mod: complete, but don't strip path names
  pages=( ${^~pages} )

  (($#mrd)) && pages[$#pages+1]=($(awk $awk $mrd))

  ##mod: grep pages
  # Build a list of matching pages that pass the grep
  local matching_pages
  typeset -a matching_pages

  # manpage_grep exists and not empty 
  if (( ${#manpage_grep} > 0 )); then
      for p in ${pages}; do
          zgrep "${manpage_grep}" $p > /dev/null
          if (( $? == 0 )); then
              #echo "$p matched $manpage_grep"
              matching_pages+=($p)
          fi
      done
  else
  # there's no manpage_grep, so all pages match
      matching_pages=( ${pages} )
  fi

  #echo "\nmatching manpages: "${matching_pages}
  pages=( ${matching_pages}(N:t) )
  # keep the stripped prefix for now
  #PREFIX=${orig_prefix}


  # Remove any compression suffix, then remove the minimum possible string
  # beginning with .<->: that handles problem cases like files called
  # `POSIX.1.5'.


  [[ $OSTYPE = solaris* ]] && sopt='-s '
  if ((CURRENT > 2)) ||
      ! zstyle -t ":completion:${curcontext}:manuals.$sect" insert-sections
  then
    compadd "$@" - ${pages%.(?|<->*(|.gz|.bz2|.Z))}
  else
    compadd "$@" -P "$sopt$sect " - ${pages%.(?|<->*(|.gz|.bz2|.Z))}
  fi
}

但是，它仍然无法完全正常工作（如果您取消注释 #echo "$p matches $manpage_grep" 行，您可以看到它确实构建了列表） - 我怀疑在内部某个地方，完成系统看到，例如，“zshcompctl”与前缀“不匹配” zsh:foo"，并且不显示结果匹配。 我试图在剥离 grep 字符串后保持 $PREFIX 不变，但它仍然不起作用。

无论如何，这至少应该让您开始。