如何从批处理文件中获取驱动器列表？

Question

我正在尝试获取用于系统升级的所有映射驱动器的列表，并希望通过批处理文件获取此信息。 我怎样才能做到这一点？

对于奖励积分： 如何编写新服务器上这些驱动器映射的脚本？

Answer 1

当前映射的列表将由以下方式返回

net use

传输将像这样工作（为了有趣¹，让我们在批处理脚本而不是 VBScript 中执行此操作）：

@echo off

setlocal EnableDelayedExpansion

set letter=.
set uncpath=.
set colon=.

for /f "delims=" %%l in ('net use') do @(
  for /f "tokens=2" %%t in ("%%l") do @set letter=%%t
  for /f "tokens=3" %%t in ("%%l") do @set uncpath=%%t

  set colon=!letter:~1,1!

  if "!colon!" EQU ":" (
    echo if exist !letter! net use !letter! /delete
    echo net use !letter! !uncpath! /persistent:yes
  )
)

endlocal

输出如下所示：

if exist M: net use M: /delete
net use M: \\someserver\someshare /persistent:yes
if exist N: net use N: /delete
net use N: \\otherserver\othershare /persistent:yes

只需存储该内容在批处理文件中，您就可以开始了。

---

¹ 事实上，“有趣”这个词用在这里并不恰当。 ;-)

Answer 2

列出映射的驱动器

Net Use

映射新驱动器

Net Use G: \\Server\Path

Answer 3

您可以使用 vbscript 来完成此操作

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set colDrives = objFSO.Drives

For Each objDrive in colDrives
    Wscript.Echo "Drive letter: " & objDrive.DriveLetter
Next

并且可以使用以下命令映射网络驱动器

Set objNetwork = CreateObject("WScript.Network") 
objNetwork.MapNetworkDrive "G:", "\\Server\Path"