awk：根据行的存在修改或追加行

Question

我有一个小的 awk 脚本，可以进行一些就地文件修改（修改为 Java .properties 文件，以给您一个想法）。 这是影响一群用户的部署脚本的一部分。

我希望能够设置默认值，将文件的其余部分保留在用户的首选项中。 这意味着如果缺少配置行，则追加配置行；如果存在则修改它，其他所有内容保持原样。

目前我使用的是这样的：

# initialize
BEGIN {
  some_value_set      = 0
  other_value_set     = 0

  some_value_default  = "some.value=SOME VALUE"
  other_value_default = "other.value=OTHER VALUE"
}

# modify existing lines
{
  if (/^some\.value=.*/) 
  {
    gsub(/.*/, some_value_default)
    some_value_set = 1
  }
  else if (/^other\.value=.*/)
  {
    gsub(/.*/, other_value_default)
    other_value_set = 1
  }
  print $0
}

# append missing lines
END {
  if (some_value_set   == 0) print some_value_default
  if (other_value_set  == 0) print other_value_default
}

尤其是当我要控制的行数变大时，这越来越麻烦。 我的 awk 知识并不是那么丰富，上面的内容感觉是错误的 - 我怎样才能简化它？

PS：如果可能的话，我想继续使用awk。 请不要仅仅建议使用 Perl/Python/任何会更容易的语言。 :-)

Answer 1

BEGIN {
    defaults["some.value"]  = "SOME VALUE"
    defaults["other.value"] = "OTHER VALUE"
}

{
    for (key in defaults) {
        pattern = key
        gsub(/\./, "\\.", pattern)
        if (match($0, "^" pattern "=.*")) {
            gsub(/=.*/, "=" defaults[key])
            delete defaults[key]
        }
    }
    print $0
}

END {
    for (key in defaults) {
        print key "=" defaults[key]
    }
}

Answer 2

我的 AWK 已经生锈了，所以我不会提供实际的代码。

• 使用正则表达式和值初始化数组。
• 对于每一行，迭代数组并进行适当的替换。 清理使用过的条目。
• 最后，迭代数组并为剩余条目追加行。