如何从值创建节点集

Question

我们如何从值创建一个节点集......

我有 n 个数字 1,2,3.......n。

我想创建一个节点集

<MYNMUMS>
<MYNUM>1</MYNUM>
<MYNUM>2</MYNUM>
<MYNUM>3</MYNUM>
<MYNUM>4</MYNUM>
....
<MYNUM>N</MYNUM>
</MYNMUMS>

Answer 1

就这么简单：

XSLT 1.0 解决方案：

此转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/">
     <MyNums>
       <xsl:call-template name="generateNumNodes">
         <xsl:with-param name="pStart" select="1"/>
         <xsl:with-param name="pEnd" select="10"/>
       </xsl:call-template>
     </MyNums>
    </xsl:template>

    <xsl:template name="generateNumNodes">
      <xsl:param name="pStart"/>
      <xsl:param name="pEnd"/>

      <xsl:if test="$pEnd >= $pStart">
        <xsl:variable name="vNumNodes"
           select="$pStart -$pEnd+1"/>

        <xsl:choose>
          <xsl:when test="$vNumNodes = 1">
            <MyNum><xsl:value-of select="$pStart"/></MyNum>
          </xsl:when>
          <xsl:otherwise>
            <xsl:variable name="vHalf" select=
              "floor(($pStart+$pEnd) div 2)"/>
            <xsl:call-template name="generateNumNodes">
              <xsl:with-param name="pStart" select="$pStart"/>
              <xsl:with-param name="pEnd" select="$vHalf"/>
            </xsl:call-template>

            <xsl:call-template name="generateNumNodes">
              <xsl:with-param name="pStart" select="$vHalf+1"/>
              <xsl:with-param name="pEnd" select="$pEnd"/>
            </xsl:call-template>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:if>
    </xsl:template>
</xsl:stylesheet>

当应用于任何 XML 文档（未使用）时，会产生所需的输出：

<MyNums>
   <MyNum>1</MyNum>
   <MyNum>2</MyNum>
   <MyNum>3</MyNum>
   <MyNum>4</MyNum>
   <MyNum>5</MyNum>
   <MyNum>6</MyNum>
   <MyNum>7</MyNum>
   <MyNum>8</MyNum>
   <MyNum>9</MyNum>
   <MyNum>10</MyNum>
</MyNums>

< strong>请注意以下事项：

1. 模板 generateNumNodes 递归调用自身。

2. 此递归在时间( O(N) ) 和空间( O(log2(N)) ) 上都高效并且实用确实会溢出堆栈——这里没有！

3. 上述功能是通过在 DVC 中实现递归（DiVide and Conquer）风格来实现的。

4. 与尾递归不同它将在任何兼容的XSLT处理器上成功执行。

5. 生成 1000000（一百万个数字）所需的最大递归深度仅为 19。

XSLT 2.0 解决方案：

更基本，无递归，仅使用 XPath 2.0 to 运算符：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/">
        <MyNums>
          <xsl:for-each select="1 to 10">
            <MyNums>
              <xsl:sequence select="."/>
            </MyNums>
          </xsl:for-each>
        </MyNums>
    </xsl:template>
</xsl:stylesheet>

Answer 2

XSLT 是一种转换语言。 当您已经拥有 XML 文档形式的一些数据，并且希望将其转换为不同的文档（可能是也可能不是 XML 格式）时，通常会使用它。

对于从“原始”数据开始并生成 XML 表示的任务，XSLT 不太适合。

我建议您研究不同的语言来解决这个问题。