Excel 按名称打印工作表

Question

我有一个 Excel 2007 电子表格，我想编写一个 VBA 过程来按名称打印特定的工作表。 我该怎么做呢？

例如， 我想打印 "FirstSheet"、"ThirdSheet", 和 "FourthSheet" 但不打印 "SecondSheet"。

Answer 1

如果您知道工作表名称，只需调用 PrintOut 函数，如下所示：

Sheets("Name").PrintOut

对于少量工作表，通过这种方式更容易！

Answer 2

类似以下内容应该有效：

Dim sh As Worksheet
For Each sh In ActiveWorkbook.Worksheets
        If (sh.Name = "Sheet1") Then
           sh.PrintOut
        End If
Next sh

Answer 3

Public Sub PrintByName(Names As Variant)

  Dim s As Worksheet
  Dim i As Integer

  If IsArray(Names) Then
    For Each s In ActiveWorkbook.Worksheets
      For i = 0 To UBound(Names)
        If StrComp(s.Name, Names(i), vbTextCompare) = 0 Then
          s.PrintOut
        End If
      Next i
    Next s
  End If

End Sub

调用方式：

PrintByName Array("FirstSheet", "ThirdSheet", "FourthSheet")

就运行时性能而言，嵌套循环不是最佳的。 由于 Excel 工作簿可以包含的工作表数量有限，我认为这是可以忽略不计的。 但是，使用 Collection 来包含所需的工作表名称而不是 Array 会更好。

Answer 4

不需要循环来执行此操作，一行代码就足够了：

Sheets(Array("FirstSheet", "ThirdSheet", "FourthSheet")).PrintOut Copies:=1