如何使用 mod_perl 导出只读变量？

Question

我试图通过创建一个常量来更容易地遵循一些 Perl 最佳实践 模块，导出整本书中使用的几个标量。 特别是 $EMPTY_STRING，我几乎可以在我编写的每个 Perl 脚本中使用它。 我想要的是自动导出这些标量，这样我就可以使用它们，而无需在每个脚本中显式定义它们。

#!perl
package Example::Constants;

use Exporter qw( import );
use Readonly;

Readonly my $EMPTY_STRING => q{};
our @EXPORT = qw( $EMPTY_STRING );

示例用法：

#!perl
use Example::Constants;
print $EMPTY_STRING . 'foo' . $EMPTY_STRING;

使用上面的代码会产生错误：

Global symbol "$EMPTY_STRING" requires explicit package name

如果我将 Readonly 声明更改为：

Readonly our $EMPTY_STRING => q{}; # 'our' instead of 'my'

错误将变为：

Attempt to reassign a readonly scalar

这对于 mod_perl 来说是不可能的吗？

Answer 1

您有 4 个问题：

1. 您没有包含 strict 和 warnings 编译指示
2. 最好通过 base 编译指示包含导出器（因为它设置@ISA 为您）
3. 只能导出包变量（即our 变量）
4. 模块必须以真值结尾

这是更正后的模块。

package Example::Constants;

use strict;
use warnings;
use base 'Exporter';
use Readonly;

Readonly our $EMPTY_STRING => q{};
our @EXPORT = qw( $EMPTY_STRING );

1;

嗯，我错过了关于尝试分配给只读的部分，听起来模块被加载了不止一次。 我相信 mod_perl 有一个 机制 用于加载与脚本本身。 此加载仅发生一次，因此您应该使用它。

Answer 2

我是 Readonly 模块的作者。 Readonly 的下一个版本将提供对 mod_perl 的支持，正是因为这个问题。

我知道这现在无法解决您的问题，但是......好吧，我正在努力:-)

-- Eric

Answer 3

我没有方便测试的 mod_perl 实例，所以我无法测试这些建议。 我希望他们能成功。

尝试使用 Scalar::Util::readonly 检查变量是否已标记为只读。

#!perl
package Example::Constants;

use Exporter qw( import );
use Readonly;
use Scalar::Util qw(readonly);

our $EMPTY_STRING;
our @EXPORT = qw( $EMPTY_STRING );

if ( !readonly( $EMPTY_STRING ) ) {
    Readonly $EMPTY_STRING => q{};
}

您还可以尝试 use vars：

#!perl
package Example::Constants;

use Exporter qw( import );
use Readonly;
use vars qw( $EMPTY_STRING );

Readonly $EMPTY_STRING => q{};
our @EXPORT = qw( $EMPTY_STRING );

您还可以使用 typeglob 常量：

#!perl
package Example::Constants;

use Exporter qw( import );
use Readonly;

our $EMPTY_STRING;
*EMPTY_STRING = \q{};
our @EXPORT = qw( $EMPTY_STRING );

使用 typeglob 常量似乎很完美，因为该技术的巨大限制（它需要全局包）在这里不是问题。