如何将数据重新排列为 GD::Graph 的 (x,y) 坐标？

Question

我正在编写一个程序，它接受用户的输入文件。 该文件中有一堆数字，我将读取文件中的数字并使用 GD::图表。

文件的第一行是 X 轴，文件的第二行是 X 轴对应的 Y 值以及第三、第四……等 例如：

1 2 3 4 5 
2 4 5 10 14
5 6 8 12 13

所以在上面，第一行是 x 轴，第二行是 y与 xaxis 对应的值，因此这将获取 10 个点。 (1, 2) (1, 5) (2, 4) (2, 6)....(4,10) (4,12) (5,14) (5, 13)

我计划阅读每一行数组，然后按空格或制表符分割行并将值存储在数组中。 因此，数组 1 将具有 x 轴，数组 2 将具有 y 轴，但是我应该如何在数组中存储第 3、4、5、...等行，以便它们变为 (x,y)？

此外，如何找到第一行和第二行（2 个数组）的最大值，以便为 X 轴和 Y 轴创建限制？

Answer 1

并不是您问题的真正答案，但不要错过 GD::Graph: ：数据。

除非您确定每行的第一行和最后一行是最小/最大的，否则您需要使用类似 List::Util 的 min() 和 max()。

---

我不太明白你所说的“文件的第一行是X轴，文件的第二行是Y轴，第三行、第四行……等是X轴的对应点”是什么意思。

Answer 2

您可以随时增加 x 和 y 数组。

#!/usr/bin/perl

use Data::Dumper;
use warnings;
use strict;

my @xs = ();
my @ys = ();
my $expecting_xs = 1;
my $last_xs_count;

while(<>) {
  chomp;
  my @values = split(/\s+/);
  if($expecting_xs) {
    push(@xs, @values);
    $last_xs_count = @values;
    $expecting_xs = 0;
  } else {
    if(@values != $last_xs_count) {
      die "Count mismatch";
    } 
    push(@ys, @values);
    $expecting_xs = 1;
  }
}

if(!$expecting_xs) {
  die("Odd number of lines");
}

my($xmin, $xmax) = extremes(@xs);
my($ymin, $ymax) = extremes(@ys);

print "xmin: $xmin xmax: $xmax ymin: $ymin ymax: $ymax\n";
print Dumper(\@xs), Dumper(\@ys);

sub extremes {
  my(@values) = @_;
  return undef unless @values;
  my $min = shift(@values);
  my $max = $min;
  for my $value (@values) {
    $max = $value if $value > $max;
    $min = $value if $value < $min;
  }
  return $min, $max;
}

Answer 3

哎呀，误读了问题，您想要 AoAoH 或 AoH，具体取决于第一条线之后的每条线是否代表一条线，或者都只是分别绘制的点。 如果文件中的每一行都成为图中的一条线，我会这样写：

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw/min max/;

my @x_points         = split " ", scalar <>; #read in the x axis labels
my ($x_min, $x_max)  = (sort { $a <=> $b } @x_points)[0,-1];
my ($y_min, $y_max)  = (0, 0);

#lines is an AoAoH, first layer are the lines to be drawn
#second layer is a list of coords
#third layer are the x and y coords
my @lines;
while (<>) {
    my @y_points = split;
    #if the two arrays are not the same size, we have a problem
    die "invalid file\n" unless @y_points == @x_points;

    $y_min = max($y_min, @y_points);
    $y_max = min($y_max, @y_points);

    push @lines, [ 
        map { { x => $x_points[$_], y => $y_points[$_] } }  
    0 .. $#x_points 
    ];
}

use Data::Dumper;

print "x min and max $x_min $x_max\n",
      "y min and max $y_min $y_max\n",
      "data:\n",
      Dumper(\@lines);

my $i;
for my $line (@lines) {
    $i++;
    print "line $i is made up of points: ",
        (map { "($_->{x}, $_->{y}) " } @$line), "\n";
}

如果它们只是要绘制的点，我会这样处理它：

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw/min max/;

my @x_points         = split " ", scalar <>; #read in the x axis labels
my ($x_min, $x_max)  = (sort { $a <=> $b } @x_points)[0,-1];
my ($y_min, $y_max)  = (0, 0);

#lines is an AoAoH, first layer are the lines to be drawn
#second layer is a list of coords
#third layer are the x and y coords
my @points;
while (<>) {
    my @y_points = split;
    #if the two arrays are not the same size, we have a problem
    die "invalid file\n" unless @y_points == @x_points;

    $y_min = max($y_min, @y_points);
    $y_max = min($y_max, @y_points);

    push @points,
        map { { x => $x_points[$_], y => $y_points[$_] } }
        0 .. $#x_points;
}

use Data::Dumper;

print "x min and max $x_min $x_max\n",
      "y min and max $y_min $y_max\n",
      "data:\n",
      Dumper(\@points);

print "Here are the points: ", 
    (map { "($_->{x}, $_->{y}) " } @points), "\n";