如何确定 Perl 文件句柄是读句柄还是写句柄？

Question

您将获得一个 IO::File 对象或 typeglob（\*STDOUT 或 Symbol::symbol_to_ref("main::FH")); 您将如何确定它是读句柄还是写句柄？ 无法扩展接口来传递此信息（我正在覆盖 close 以在实际关闭之前添加对 flush 和 sync 的调用）。

目前，我正在尝试刷新和同步文件句柄并忽略错误“无效参数”（这是我尝试时得到的结果） code>flush 或 sync 读取文件句柄）：

eval { $fh->flush; 1 } or do {
        #this seems to exclude flushes on read handles
        unless ($! =~ /Invalid argument/) {
                croak "could not flush $fh: $!";
        }
};

eval { $fh->sync; 1 } or do {
        #this seems to exclude syncs on read handles
        unless ($! =~ /Invalid argument/) {
                croak "could not sync $fh: $!";
        }
};

Answer 1

查看 fcntl 选项。 也许将 F_GETFL 与 O_ACCMODE 结合使用。

编辑：我在午餐时进行了一些谷歌搜索和玩，这里有一些可能不可移植代码，但它适用于我的 Linux 机器，可能还适用于任何 Posix 系统（甚至可能是西格温，谁知道呢？）。

use strict;
use Fcntl;
use IO::File;

my $file;
my %modes = ( 0 => 'Read only', 1 => 'Write only', 2 => 'Read / Write' );

sub open_type {
    my $fh = shift;
    my $mode = fcntl($fh, F_GETFL, 0);
    print "File is: " . $modes{$mode & 3} . "\n";
}

print "out\n";
$file = new IO::File();
$file->open('> /tmp/out');
open_type($file);

print "\n";

print "in\n";
$file = new IO::File();
$file->open('< /etc/passwd');
open_type($file);

print "\n";

print "both\n";
$file = new IO::File();
$file->open('+< /tmp/out');
open_type($file);

输出示例：

$ perl test.pl 
out
File is: Write only

in
File is: Read only

both
File is: Read / Write