vbscript 字符串中的引号导致 wsh 无效 url 错误

Question

我试图让下面的脚本生成这样的快捷方式：

“C:\Program Files\Internet Explorer\iexplore.exe” http://WebApp/index.aspx

set WshShell = WScript.CreateObject("WScript.Shell")
strDesktop = WshShell.SpecialFolders("Desktop")
set oUrlLink = WshShell.CreateShortcut(strDesktop & "\WebApp.url")
oUrlLink.TargetPath = ""&chr(34)& _
  "C:\Program Files\Internet Explorer\iexplore.exe" & _
   chr(34)&" http://WebApp/index.aspx"
oUrlLink.Save

但是它似乎不喜欢引号。

我在 URL 中收到无效语法： ""C:\Program Files\Internet Explorer\iexplore.exe" http://WebApp /index.aspx”。

如何在 VBScript 不打结的情况下嵌入 " ？

Answer 1

这是根据 Microsoft 的说法：

Set objShell = CreateObject("Wscript.Shell")
strFolder = objShell.SpecialFolders.Item("Desktop")
Set objShortcut = objShell.CreateShortcut(strFolder & "\Open Web Site.lnk")
objShortcut.TargetPath = "C:\Program Files\Internet Explorer\iexplore.exe"
objShortcut.Arguments = "http://WebApp/index.aspx"
objShortcut.Save

您必须使用 .lnk 作为文件扩展名，而不是 .url，因为 .Arguments 属性仅适用于 .lnk

Answer 2

这有效吗？

oUrlLink.TargetPath = "C:\Program Files\Internet Explorer\iexplore.exe"
oUrlLink.Arguments = "http://WebApp/index.aspx"
oUrlLink.Save

Answer 3

在 VB 中转义引号 - 总是很痛苦。

oUrlLink.TargetPath = """C:\Program Files\Internet Explorer\iexplore.exe"" http://WebApp/index.aspx"

Answer 4

你试过这个吗？

oUrlLink.TargetPath = chr(34) & "C:\Program Files\Internet Explorer\iexplore.exe" & _
                      chr(34) & " http://WebApp/index.aspx"

有关引用的更多信息，请访问此处。

Answer 5

这对我有用：

set WshShell = WScript.CreateObject("WScript.Shell")
strDesktop = WshShell.SpecialFolders("Desktop")
set oUrlLink = WshShell.CreateShortcut(strDesktop & "\WebApp.url")
oUrlLink.TargetPath = "C:\Program Files\Internet Explorer\iexplore.exe http://WebApp/index.aspx"
oUrlLink.Save

Answer 6

用这个作为目标路径

"C:\Program Files\Internet Explorer\iexplore.exe http://WebApp/index.aspx"

这个怎么样

Target= "http://WebApp/index.aspx"

Answer 7

Set objShell = WScript.CreateObject("WScript.Shell" )
strDesktopFolder = objShell.SpecialFolders("Desktop") 
Set objShortCut = objShell.CreateShortcut(strDesktopFolder & "\test.lnk" ) 
objShortCut.TargetPath = "http://www.google.com/" 
objShortCut.Description = "Test Environment" 
objShortCut.Save 

---

上面的方法对我来说效果很好，可以将快捷方式部署到桌面作为 GPO 的一部分。 为了保护无辜者，这些名字已被更改。

我的想法似乎更清晰一些，但无论如何我都不是脚本大师。